2 brza načina za izdvajanje odjeljaka iz vašeg Word dokumenta

U ovom članku ćemo vam ponuditi 2 brza i jednostavna načina za izdvajanje odjeljaka iz Word dokumenta u drugi ili nekoliko.

Često se dešava da se sadržaj izvuče iz jednog dokumenta u drugi. I u našem prethodnom članku, raspravljali smo o tome kako izdvojiti stranice iz dokumenta. Za detaljnije informacije možete pogledati ovaj članak: 2 brza načina za izdvajanje pojedinačnih stranica iz Word dokumenta

Danas ćemo vam pokazati kako ekstrahirati po sekcijama.    

Metoda 1: Izdvoj trenutni odjeljak u novi dokument

1. Prvo, postavite kursor u ciljni odjeljak.
2. Zatim pritisnite “Alt+ F11” da biste pozvali VBA editor u Wordu.
3. Zatim u lijevoj koloni kliknite na “Normalno”.
4. I na traci menija kliknite na “Insert”.
5. Zatim odaberite “Module” na tom padajućem izborniku.
6. Dvaput kliknite da otvorite novi modul i tamo zalijepite sljedeće kodove:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Zatim kliknite na “Run” na traci menija ili pritisnite “F5”.
8. Zatim će se pojaviti prozor "Pretraži". Odaberite mjesto za pohranjivanje novog dokumenta i kliknite na “OK”.
9. I u polje „Naziv datoteke“ unesite naziv nove datoteke i kliknite „U redu“.

Sada ste izdvojili odjeljak u novi dokument.

Metoda 2: Izdvojite svaki odjeljak u dokumentu u pojedinačne nove

Ovaj način vam može pomoći u grupnoj obradi svih odjeljaka u dokumentu. Naravno, biće nam potreban i makro.

1. Za početak, otvorite ciljni dokument.
2. Zatim slijedite korake iz metode 1 da biste instalirali i pokrenuli makro.
3. Samo ovaj put taj makro zamijenite ovim:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Ipak, u prozoru "Pretraži" odaberite putanju za skladištenje i kliknite "OK".

Popravite iritirajuće greške u riječi

Uobičajeno je naići na neke Word greške dok ga koristite. Može biti neugodno, moramo odvojiti vrijeme povratiti riječ što je brže moguće. Jer što duže odlažemo, gubitak podataka može biti ozbiljniji. Stoga se predlaže da unaprijed nabavite servis za popravku.

Uvod za autora:

Vera Chen je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen xls i pdf popravak softverskih proizvoda. Za više informacija posjetite www.datanumen.com