2 brza načina za izdvajanje pojedinačnih stranica iz Word dokumenta

U današnjem postu želimo s vama podijeliti 2 brza načina za izdvajanje pojedinačnih stranica iz vašeg Word dokumenta.

Ponekad u Word dokumentu svaka stranica može sadržavati prilično nezavisan sadržaj, kao što je tabela. I vjerovatno ćete morati poslati različite tabele različitim ljudima. Zatim ćete morati da sačuvate svaku tabelu koja je svaka stranica, kao zaseban fajl.

Prva ideja koja nam padne na pamet trebala bi biti klasično kopiranje i lijepljenje. Ipak, sve što uključuje selekciju ponekad može biti neugodno, jer povlačenjem i odabirom možete lako završiti bez izbora. Iz tog razloga, preporučujemo vam 2 brze metode pomoću makroa za obavljanje posla.

Metoda 1: Izdvojite trenutnu stranicu i sačuvajte je kao novi dokument

1. Prvo i najvažnije, postavite kursor na stranicu koju želite izdvojiti.
2. Kliknite na karticu "Developer", a zatim kliknite na "Visual Basic" da biste pozvali VBA editor. Ako “Developer” nije aktiviran, jednostavno pritisnite “Alt+ F11”.
3. Drugo, idite na “Normal” projekat klikom na njega.
4. Zatim kliknite na karticu "Insert" i odaberite "Module".
5. Dvaput kliknite na novi modul da otvorite područje za uređivanje.
6. Zatim tamo zalijepite sljedeće kodove:

Sub SaveCurrentPageAsANewDoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim strFileName As String
  Dim strFolder As String
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
  strFileName = InputBox("Enter file name here: ")
 
  '  Copy current page.
  objDoc.Bookmarks("\Page").Range.Select
  Selection.Copy
 
  '  Open a new document to paste the selection.
  Set objNewDoc = Documents.Add
  Selection.Paste
 
  objNewDoc.SaveAs FileName:=strFolder & "\" & strFileName & ".docx"
  objNewDoc.Close
End Sub

7. Na kraju, kliknite na dugme "Pokreni".

Sada će postojati 2 polja za unos. Unesite putanju na kojoj želite da pohranite novi dokument u prvom polju za unos. I unesite novi naziv dokumenta na drugom.

Metoda 2: Izvucite svaku stranicu i sačuvajte je kao novi dokument

Sljedeći makro će vam omogućiti da izdvojite svaku pojedinačnu stranicu dokumenta.

1. Prvo pritisnite “Ctrl+ Home” da biste otišli na sam početak vašeg dokumenta.
2. Zatim slijedite iste korake u metodi 1 da biste instalirali i pokrenuli makro.
3. Ovaj put zamijenite makro sa ovim:

Sub SaveEachPageAsADoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim nPageNumber As Integer
  Dim strFolder As String
  Dim objFileName As Range
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
 
  '  Copy each page in the document to paste it into a new one.
  For nPageNumber = 1 To ActiveDocument.ComputeStatistics(wdStatisticPages)
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Copy
 
    Set objNewDoc = Documents.Add
    Selection.Paste
 
    '  Save new doc with the name of "Page" & nPageNumber and get the first 20 characters of the new doc as part of the file name.
    Set objFileName = objNewDoc.Range(Start:=0, End:=20)
    objNewDoc.SaveAs FileName:=strFolder & "\" & "Page " & nPageNumber & " " & objFileName & ".docx"
    objNewDoc.Close
    Application.Browser.Next
  Next nPageNumber
End Sub

Pozabavite se problemima sa riječima

Uvijek će postojati razni problemi s Wordom. Poenta je naučiti ih pravilno rješavati. Najpreporučljiviji način je, naravno, nabaviti sofisticirani... Oporavak riječi alat. Trebali biste iskoristiti svaku minutu da povratite svoje podatke prije nego što bude prekasno.

Uvod za autora:

Vera Chen je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući corrupt xlsx i pdf popravak softverskih proizvoda. Za više informacija posjetite www.datanumen.com