কীভাবে স এর সুনির্দিষ্ট স্লাইডগুলি দ্রুত সংযুক্ত করবেন PowerPoint আপনার আউটলুক ইমেল উপস্থাপনা

এখন শেয়ার:

আপনি যদি স এর নির্দিষ্ট স্লাইডগুলি বের করতে চান PowerPoint একটি পৃথক নতুন উপস্থাপনা উপস্থাপনা এবং এটি একটি আউটলুক ইমেলের সাথে সংযুক্ত করে, আপনি এই নিবন্ধে ভাগ করা উপায়টি ব্যবহার করতে পারেন।

পরিবর্তে একটি সম্পূর্ণ সংযুক্তি PowerPoint কোনও ইমেলের কাছে উপস্থাপনা, যদি আপনি উপস্থাপনার নির্দিষ্ট স্লাইডগুলি সংযুক্ত করতে চান তবে সাধারণভাবে আপনাকে প্রথমে একটি নতুন উপস্থাপনায় নির্দিষ্ট স্লাইডগুলি অনুলিপি করতে হবে। এটা খুব ঝামেলা। অতএব, এখানে আমরা আপনাকে এমন একটি পদ্ধতি দেখাব যা এটি একসাথে উপলব্ধি করতে পারে।

এর নির্দিষ্ট স্লাইডগুলি দ্রুত সংযুক্ত করুন PowerPoint আপনার আউটলুক ইমেল উপস্থাপনা

এর নির্দিষ্ট স্লাইডগুলি সংযুক্ত করুন PowerPoint একটি ইমেল উপস্থাপনা

  1. প্রথমে, নির্দিষ্টটি খুলুন PowerPoint উপস্থাপনা।
  2. তারপরে, PowerPoint অ্যাপ্লিকেশন উইন্ডো, ভিবিএ সম্পাদক অ্যাক্সেস করতে "Alt + F11" কী টিপুন।
  3. এর পরে, নতুন উইন্ডোতে, "সন্নিবেশ"> "মডিউল" টিপুন একটি নতুন মডিউল তৈরি করুন।
  4. পরবর্তীকালে, এই মডিউলটিতে নিম্নলিখিত ভিবিএ কোডটি অনুলিপি করুন এবং আটকান।
Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

ভিবিএ কোড - এর নির্দিষ্ট স্লাইড সংযুক্ত করুন PowerPoint একটি ইমেল উপস্থাপনা

  1. এর পরে, আপনি বর্তমান উইন্ডোটি বন্ধ করতে পারেন।
  2. পরে, দ্রুত অ্যাক্সেস সরঞ্জামদণ্ডে নতুন ম্যাক্রো যুক্ত করতে "ফাইল"> "বিকল্পগুলি"> "দ্রুত অ্যাক্সেস সরঞ্জামদণ্ড" এ যান।
  3. অবশেষে, আপনি এই ম্যাক্রো চেষ্টা করতে পারেন।
  • শুরুতে, আপনি যে নির্দিষ্ট স্লাইডগুলো বের করতে চান, সেগুলো নির্বাচন করুন।
  • তারপরে, কুইক অ্যাক্সেস সরঞ্জামদণ্ডে ম্যাক্রো বোতামটি ক্লিক করুন।নির্বাচিত স্লাইডগুলিতে ম্যাক্রো চালান
  • একবারে, একটি আউটলুক ইমেল প্রদর্শিত হবে, যেখানে একটি আছে PowerPoint উত্স উপস্থাপনা থেকে নিষ্কাশন করা উপস্থাপনা।এক্সট্রাক্ট উপস্থাপনা স্লাইড

কার্যকর পুনরুদ্ধার সরঞ্জামটি ব্যবহার করুন

যেমনটি আমরা সবাই জানি, আউটলুক একটি অন্তর্নির্মিত মেরামত ইউটিলিটি সহ সমৃদ্ধ - স্ক্যানপস্ট। তবুও, এটি সহজেই আউটলুকের ছোট ছোট সমস্যাগুলির সাথে লড়াই করতে পারে। আপনি যা মুখোমুখি হন তা যদি গুরুতর ক্ষতি হয় তবে তা কার্যকর হবে না। এই মুহুর্তে, আপনার কাছে আর কোনও শক্তিশালী এবং বিশ্বাসযোগ্য মেরামতের সরঞ্জামটি পুনরাবৃত্তি করা ছাড়া বিকল্প নেই DataNumen Outlook Repair। এটির সাহায্যে আপনি আপনার দূষিত আউটলুক ফাইলটি উদ্ধার করতে সক্ষম হবেন।

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় দূষিত এমডিএফ এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com

এখন শেয়ার:

মন্তব্যসমূহ বন্ধ করা হয়.