একাধিক আউটলুক বার্তা (.msg) ফাইলগুলি থেকে কীভাবে সমস্ত প্রাপককে দ্রুত বের করতে হয়

কিছু ব্যবহারকারী আউটলুক ইমেলগুলি থেকে সংরক্ষিত একাধিক আউটলুক বার্তা ফাইলগুলি থেকে সমস্ত প্রাপককে দ্রুত বের করতে চান। এখন, এই পিost একটি দ্রুত পদ্ধতির ভাগ করে নেওয়ার জন্য এটি তাকান।

একটি একক আউটলুক বার্তা ফাইল থেকে প্রাপককে বের করতে, আপনি এটি খোলার জন্য ডাবল ক্লিক করতে পারেন এবং তারপরে খোলার বার্তা উইন্ডোতে প্রাপকদের অনুলিপি করতে পারেন। তবে, যদি আপনাকে আউটলুক বার্তা ফাইলগুলির একটি ব্যাচ মোকাবেলা করতে হয়, ম্যানুয়াল পদ্ধতিটি যথেষ্ট দক্ষ নয়। সুতরাং, আপনি আরও কার্যকর উপায় জন্য সন্ধান করতে পারেন। এখানে আমরা আপনার সাথে এরকম একটি পরিচয় করিয়ে দেব। এর বিশদ পেতে পড়ুন।

একাধিক আউটলুক বার্তা (.msg) ফাইল থেকে সমস্ত প্রাপককে বের করুন

1. সেই জন্যtart, "অনুযায়ী অনুযায়ী আউটলুক ভিবিএ সম্পাদকটিতে অ্যাক্সেস পানআপনার আউটলুকে কীভাবে ভিবিএ কোড চালাবেন"।
2. এরপরে, নিম্নলিখিত ভিবিএ কোডটি খালি মডিউলে কপি এবং পেস্ট করুন paste

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. তারপরে, প্রথম সাবরোটিনে কার্সারটি সরান।
4. এরপরে, "রান" বোতামটি ক্লিক করুন বা "F5" কী টিপুন।
5. তারপরে, পপআপ ডায়ালগ বাক্সে, উইন্ডোজ ফোল্ডারটি নির্বাচন করুন যার উত্স আউটলুক বার্তা (.msg) ফাইল রয়েছে।
6. নির্বাচনের পরে, ম্যাক্রো চালিয়ে যেতে দিতে "ঠিক আছে" ক্লিক করুন।
7. ম্যাক্রো শেষ হয়ে গেলে, সমস্ত উত্তোলিত প্রাপকের ইমেল ঠিকানাগুলির তালিকাভুক্ত একটি বার্তা প্রদর্শিত হবে, যেমন নীচের স্ক্রিনশটটিতে দেখানো হয়েছে।

আপনার আউটলুক ডেটা বিপদ থেকে রক্ষা করুন

আউটলুক ডেটা স্বীকার করে দুর্নীতির ঝুঁকির মধ্যে রয়েছে। অতএব, আউটলুক ডেটা রক্ষা করা এটি বেশ কঠোর কাজ। এটি আপনাকে আউটলুক ডেটার জন্য নিয়মিত ব্যাকআপ তৈরিতে অধ্যবসায় করা প্রয়োজন। এছাড়াও, যদি সম্ভব হয় তবে এটি অভিজ্ঞ এবং পেশাদার আউটলুক প্রস্তুত করার জন্য বুদ্ধিমান এবং সুপারিশ করা হয় পিএসটি মেরামত সরঞ্জাম, মত DataNumen Outlook Repair, যাতে আপনি আউটলুক দুর্নীতির ঘটনায় তাত্ক্ষণিকভাবে এবং সময়মতো উদ্ধার পেতে পারেন।

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় পুনরুদ্ধার Sql Server এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com