আপনার আউটলুকের স্থিতি অনুসারে কীভাবে সমস্ত কাজ দ্রুত গণনা করবেন

টাস্কের পাঁচটি স্ট্যাটাস থাকতে পারে – “শুরু হয়নি”, “চলমান”, “সম্পন্ন”, “অন্যের জন্য অপেক্ষারত” এবং “স্থগিত”। আপনি যদি স্ট্যাটাস অনুযায়ী দ্রুত সমস্ত টাস্ক গণনা করতে চান, তাহলে এই আর্টিকেলে বর্ণিত পদ্ধতিটি ব্যবহার করতে পারেন।

আউটলুক ব্যবহারকারীদের টাস্ক বা ফ্ল্যাগ করা আইটেমগুলিতে স্ট্যাটাস নির্ধারণ করতে সহায়তা করে। এর পাঁচটি স্ট্যাটাস রয়েছে – যথাক্রমে “শুরু হয়নি”, “চলমান”, “সম্পন্ন”, “অন্য কারো জন্য অপেক্ষারত” এবং “স্থগিত”। সম্ভবত আপনার আউটলুকে প্রচুর পরিমাণে টাস্ক রয়েছে এবং সেগুলি বিভিন্ন স্ট্যাটাসে আছে। এখন, আপনি যদি স্ট্যাটাস অনুযায়ী সমস্ত টাস্ক গণনা করতে চান, তাহলে আপনি নিম্নলিখিত পদ্ধতিটি ব্যবহার করতে পারেন।

স্ট্যাটাস অনুসারে দ্রুত সমস্ত কাজ গণনা করুন

1. প্রথমে, "উল্লেখ করে আউটলুক ভিবিএ সম্পাদক চালু করুনআপনার আউটলুকে কীভাবে ভিবিএ কোড চালাবেন"।
2. তারপর, VBA এডিটরে, “MS Excel Object Library” এবং “MS Scripting Runtime”-এর রেফারেন্সগুলো “নির্দেশনা অনুযায়ী” সক্রিয় করুন।VBA-তে কীভাবে একটি অবজেক্ট লাইব্রেরি রেফারেন্স যুক্ত করবেন"।
3. এরপরে, নিম্নলিখিত কোডটি একটি অব্যবহৃত মডিউলে অনুলিপি করুন।

Dim objDictionary As New Scripting.Dictionary

Sub CountTasksByStatus()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varStatuses As Variant
    Dim varTaskCounts As Variant
    Dim i As Integer
    Dim nLastRow As Integer
 
    'Count by Dictionary
    Set objDictionary = CreateObject("Scripting.Dictionary")
  
    'Process All Outlook data files
    For Each objStore In Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olTaskItem Then
               Call ProcessTaskFolders(objFolder)
            End If
        Next
    Next
 
    'Export the counts to an Excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
        .Cells(1, 1) = "Status"
        .Cells(1, 1).Font.Bold = True
        .Cells(1, 2) = "Task Count"
        .Cells(1, 2).Font.Bold = True
    End With
 
    varStatuses = objDictionary.Keys
    varTaskCounts = objDictionary.Items
 
    For i = LBound(varStatuses) To UBound(varStatuses)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
            .Cells(nLastRow, 1) = varStatuses(i)
            .Cells(nLastRow, 2) = varTaskCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

Sub ProcessTaskFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objTask As Outlook.TaskItem
    Dim strStatus As String
    Dim objSubfolder As Outlook.Folder
 
    'Count tasks by status
    For Each objTask In objCurFolder.Items
        Select Case objTask.Status
               Case olTaskNotStarted
                    strStatus = "Not Started"
 
                    If objDictionary.Exists(strStatus) Then
                       objDictionary(strStatus) = objDictionary(strStatus) + 1
                    Else
                       objDictionary.Add strStatus, 1
                    End If
               Case olTaskInProgress
                    strStatus = "In Progress"
 
                    If objDictionary.Exists(strStatus) Then
                       objDictionary(strStatus) = objDictionary(strStatus) + 1
                    Else
                       objDictionary.Add strStatus, 1
                    End If
               Case olTaskComplete
                    strStatus = "Completed"
 
                    If objDictionary.Exists(strStatus) Then
                       objDictionary(strStatus) = objDictionary(strStatus) + 1
                    Else
                       objDictionary.Add strStatus, 1
                    End If
               Case olTaskWaiting
                    strStatus = "Waiting on someone else"
 
                    If objDictionary.Exists(strStatus) Then
                       objDictionary(strStatus) = objDictionary(strStatus) + 1
                    Else
                       objDictionary.Add strStatus, 1
                    End If
               Case olTaskDeferred
                    strStatus = "Deferred"
 
                    If objDictionary.Exists(strStatus) Then
                       objDictionary(strStatus) = objDictionary(strStatus) + 1
                    Else
                       objDictionary.Add strStatus, 1
                    End If
         End Select
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessTaskFolders(objSubfolder)
       Next
    End If
End Sub

4. এর পরে, প্রথম সাবরুটিনে ক্লিক করুন এবং "F5" কী টিপুন।
5. একবারে, যখন ম্যাক্রো সম্পূর্ণ হবে, নীচের স্ক্রিনশটের মতো একটি নতুন এক্সেল ওয়ার্কশিট প্রদর্শিত হবে। এটিতে বিভিন্ন স্ট্যাটাসে কাজের সংখ্যা রয়েছে।

আউটলুকের আশেপাশের সমস্যাগুলি থেকে সাবধান থাকুন

আউটলুকের চারপাশে প্রচুর পরিমাণে ঝুঁকি রয়েছে যার মধ্যে রয়েছে ভাইরাস, মানব ত্রুটি, সফ্টওয়্যার ত্রুটিগুলি এবং পাশাপাশি হার্ডওয়্যার ব্যর্থতা ইত্যাদি Therefore অতএব, যদি আপনার মূল্যবান আউটলুক ডেটা হারাতে না চান তবে আপনাকে সর্বদা সতর্ক থাকতে হবে। সহজ কথায় বলতে গেলে, ইমেলগুলিতে আপনার কখনও অজানা সংযুক্তি বা সন্দেহজনক লিঙ্কগুলি ডাউনলোড করা উচিত নয়। তদতিরিক্ত, যদি সম্ভব হয় তবে এটি উল্লেখযোগ্য আউটলুক ফিক্স ইউটিলিটি রাখার পরামর্শ দেওয়া হয় DataNumen Outlook Repair, আশেপাশে, সম্পূর্ণরূপে উপর নির্ভর করে না ইনবক্স মেরামতের সরঞ্জাম.

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় পুনরুদ্ধার এসকিএল এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com