কীভাবে ব্যাচ করবেন আপনার আউটলুকের সমস্ত পঠন প্রাপ্তি মুছুন

প্রাপকরা আপনার ইমেল পড়েছেন কিনা তা নিশ্চিত করতে, ইমেল লেখার সময় আপনি 'রিড রিসিপ্ট' (read receipt) এর জন্য অনুরোধ করতে পারেন। এই পরিস্থিতিতে, আপনার মেইলবক্স এই ধরনের 'রিড রিসিপ্ট' দিয়ে ভরে যেতে পারে। এখন, এই পোস্টে আপনাকে শেখানো হবে কীভাবে একসাথে অনেকগুলো ইমেল স্থায়ীভাবে মুছে ফেলা যায়।

নিবন্ধটি পড়ার পরে “কীভাবে ব্যাচ করবেন আপনার আউটলুকের সমস্ত বিতরণ প্রাপ্তি মুছুন“, আপনি সমস্ত পড়ার প্রাপ্তি মুছে ফেলার জন্য বাল্কের পদ্ধতির বিষয়ে ভাবতে পারেন। প্রকৃতপক্ষে, দুই ধরণের প্রাপ্তির মধ্যে প্রকাশের পার্থক্য তাদের বিষয়। বিতরণ রসিদে বিষয়টি "বিতরণ" থাকে তবে পঠনের রশিদে এর পরিবর্তে "পড়ুন" থাকে। অতএব, আপনি ব্যাচের জন্য একইভাবে সমস্ত পড়ার প্রাপ্তিগুলি মুছতে পারেন। নিম্নলিখিতগুলিতে, আমরা আপনাকে বিশদ পদক্ষেপগুলি শিখিয়ে দেব।

ব্যাচ সমস্ত পড়ার প্রাপ্তি মুছুন

1. শুরুতেই আপনার Outlook চালু করুন।
2. তারপরে, “Alt + F11” এর মাধ্যমে আউটলুক ভিবিএ সম্পাদকটিতে যান “আপনার আউটলুকে কীভাবে ভিবিএ কোড চালাবেন"।
3. এর পরে, নতুন উইন্ডোতে, একটি খালি মডিউল খুলুন এবং এর মধ্যে নিম্নলিখিত কোডটি দিন।

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. এর পরে, প্রথম সাবরোটিনে ক্লিক করুন।
5. অবশেষে, "F5" কী বোতাম টিপুন।
6. একবারে, ম্যাক্রো আপনার আউটলুক থেকে সমস্ত পঠন প্রাপ্তি মুছতে কাজ করবে।
7. এটি শেষ হয়ে গেলে, আপনি নীচের স্ক্রিনশটের মতো ফলাফল সম্পর্কে একটি প্রম্পট পাবেন।
8. বর্তমানে, আপনি আপনার মেল ফোল্ডারগুলি পরীক্ষা করতে পারেন। সমস্ত পঠন প্রাপ্তি চলে গেছে।

আউটলুক ডেটা রক্ষা করুন

যদিও আউটলুক ফাইল দুর্নীতিতে স্বীকারোক্তিযুক্ত, তবে আমরা এটির সুরক্ষার জন্য পদক্ষেপ নিতে পারি। উদাহরণস্বরূপ, আমাদের আউটলুক ফাইলটি ছোট আকারে রাখা উচিত, এটি দূষিত কারণগুলি থেকে রক্ষা করা এবং নিয়মিতভাবে এটিকে ব্যাক আপ করা উচিত। সর্বশেষে তবে কম নয়, আপনি একটি শক্তিশালী বাহ্যিক পিএসটি মেরামত সরঞ্জামটি পছন্দ করতেন DataNumen Outlook Repair। এটি মেরামতের উপর দুর্দান্ত প্রভাব ফেলবে দূষিত আউটলুক ফাইল.

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় বর্গফুট মেরামত এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com