এক্সেল ওয়ার্কবুকে প্রতিটি কার্যপত্রকের ডেটা আকার পাওয়ার 2 টি দ্রুত উপায়

আপনি যদি দ্রুত কোনও এক্সেল ওয়ার্কবুকের প্রতিটি কার্যপত্রকের ডেটা আকার পেতে চান তবে আপনি এই নিবন্ধটি উল্লেখ করতে পারেন। এখানে আমরা আপনার সাথে 2 টি সহজ পদ্ধতি ভাগ করব।

অনেক সময়, একটি এক্সেল ওয়ার্কবুকের সাথে কাজ করার সময় যা প্রচুর পরিমাণে কার্যপত্রক নিয়ে থাকে, আপনি প্রতিটি কার্যপত্রকের ডেটা আকার পেতে চাইতে পারেন। তবে এই প্রয়োজনীয়তার জন্য কোনও স্থানীয় বৈশিষ্ট্য নেই। সুতরাং, আপনাকে কয়েকটি কার্যপদ্ধতি ব্যবহার করতে হবে, যেমন নীচের পদ্ধতিটি ১ Or বা আপনি সমস্ত কার্যপত্রকের ডেটা আকারের পরিমাণে পেতে প্রচুর স্মার্ট পদ্ধতি 1 ব্যবহার করতে পারেন।

পদ্ধতি 1: ম্যানুয়ালি একের পর এক ওয়ার্কশিট ডেটা আকার পান

1. প্রথমে নির্দিষ্ট এক্সেল ওয়ার্কবুকটি খুলুন।
2. তারপরে, এক্সেল ওয়ার্কশিটের সামগ্রীগুলি অনুলিপি করুন।
3. এর পরে, একটি নতুন ওয়ার্কবুক তৈরি করুন এবং অনুলিপি করা ওয়ার্কশিটটি শীট 1 এ আটকান।
4. পরে, নতুন ওয়ার্কবুকটি একটি উইন্ডোজ ফোল্ডারে সংরক্ষণ করুন।
5. শেষ অবধি, আপনি নিম্নলিখিত স্ক্রিনশটটিতে প্রদর্শিত উইন্ডোজ এক্সপ্লোরারে কার্যপত্রকের ডেটা আকারের সমান নতুন ওয়ার্কবুকের ডেটা আকার পরীক্ষা করতে পারবেন।
6. এখন, আপনি একের পর এক অন্য কার্যপত্রকের ডেটা আকার পেতে এই উপায়টি ব্যবহার করতে পারেন।

পদ্ধতি 2: ব্যাচটি ভিবিএর মাধ্যমে সমস্ত কার্যপত্রকের ডেটা আকারগুলি পান

1. শুরু করতে, এক্সেল ভিবিএ সম্পাদকটি অনুযায়ী "খুলুনআপনার এক্সেলে কীভাবে ভিবিএ কোড চালাবেন"।
2. তারপরে, নীচের কোডটি একটি প্রকল্প বা মডিউলে রাখুন।

Sub GetEachWorksheetSize()
    Dim strTargetSheetName As String
    Dim strTempWorkbook As String
    Dim objTargetWorksheet As Worksheet
    Dim objWorksheet As Worksheet
    Dim objRange As Range
    Dim i As Long
    Dim nLastEmptyRow As Integer

    strTargetSheetName = "Sheet Sizes"
    strTempWorkbook = ThisWorkbook.Path & "\Temp Workbook.xls"

    With ActiveWorkbook.Worksheets.Add(Before:=Application.Worksheets(1))
         .Name = strTargetSheetName
         .Cells(1, 1) = "Sheet"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 2) = "Size"
         .Cells(1, 2).Font.Size = 14
         .Cells(1, 2).Font.Bold = True
    End With

    Set objTargetWorksheet = Application.Worksheets(strTargetSheetName)

    For Each objWorksheet In Application.ActiveWorkbook.Worksheets
        If objWorksheet.Name <> strTargetSheetName Then
           objWorksheet.Copy

           Application.ActiveWorkbook.SaveAs strTempWorkbook
           Application.ActiveWorkbook.Close SaveChanges:=False

           nLastEmptyRow = objTargetWorksheet.Range("A" & objTargetWorksheet.Rows.Count).End(xlUp).Row + 1

           With objTargetWorksheet
                .Cells(nLastEmptyRow, 1) = objWorksheet.Name
                .Cells(nLastEmptyRow, 2) = FileLen(strTempWorkbook)
           End With

           Kill strTempWorkbook
         End If
    Next
End Sub

3. এরপরে, এখনই এই ম্যাক্রোটি চালানোর জন্য "F5" টিপুন।
4. শেষ পর্যন্ত ম্যাক্রো শেষ হওয়ার পরে ওয়ার্কবুকে ফিরে আসুন।
5. আপনি একেবারে প্রথম দিকে একটি নতুন ওয়ার্কশিট দেখতে পাবেন, যাতে প্রতিটি চিত্রের আকার নীচের চিত্রের মতো থাকে।

তুলনা

ক্লান্তিহীন পিএসটি সমস্যাগুলি সমাধান করুন

ব্যবহারকারীরা এমএস এক্সেলে অপ্রত্যাশিতভাবে বন্ধ বা পুনরায় চালু হওয়া থেকে শুরু করে গুরুতর সমস্যা পর্যন্ত নানা ধরনের বিরক্তিকর সমস্যার সম্মুখীন হতে পারেন। xlsx দুর্নীতিনিঃসন্দেহে, সবচেয়ে জটিল সমস্যা হলো ক্ষতিগ্রস্ত এক্সেল ফাইল, কারণ এটি সহজে সমাধান করা যায় না। এর জন্য আপনাকে একটি বাহ্যিক এক্সেল ফিক্স টুল প্রয়োগ করতে হয়, যেমন DataNumen Excel Repair.

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় দূষিত SQL Server এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com