Outlook e-poçtunun bütün şəkil əlavələrini Excel iş səhifəsinə necə tez ixrac etmək olar

Outlook e-poçtunun bütün şəkil qoşmalarını Excel iş vərəqinə sürətlə ixrac etmək istəyirsinizsə, bu məqaləyə müraciət edə bilərsiniz. Burada sizə əl ilə ixrac etməkdən daha təsirli bir yol göstərəcəyik.

Çoxlu şəkil əlavələri olan bir e-poçt aldığınız zaman, onlardan Excel-də hesabat hazırlamaq üçün istifadə etmək istəyirsinizsə, bu şəkilləri Excel iş vərəqinə toplu şəkildə ixrac edə biləcək bir yol axtarmalısınız. İndi isə sizə belə bir yanaşmanı aşağıda təqdim edəcəyik.

E-poçtun bütün şəkil əlavələrini Excel İş Vərəqinə ixrac edin

1. Başlamaq üçün Outlook tətbiqinizə normal şəkildə daxil olun.
2. Sonra, Outlook pəncərəsində, "Tətbiqlər üçün Microsoft Visual Basic" pəncərəsini gətirəcək "Alt + F11" düymələri qısa yollarını basın.
3. Bu ekranda siz istifadə olunmayan modulu açmalı və ya yenisini birbaşa daxil etməlisiniz.
4. Sonra, aşağıdakı VBA kodunu bu modula köçürməlisiniz.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Bundan sonra makrodan çıxa bilərsiniz.
6. Sonra bu makronu Tez Giriş Alətlər Panelinə əlavə etmək üçün “Fayl” > “Seçimlər” > “Tez Giriş Alətlər Paneli”nə keçin.
7. Nəhayət, bu makronu indi sınaya bilərsiniz.

• Əvvəlcə mənbə e-poçtunu seçin və ya açın.
• Sonra, Tez Giriş Alətlər Panelində makro düyməsini basın.
• Makro tamamlandıqda, aşağıdakı ekran görüntüsü kimi göstərilən Excel iş vərəqi alacaqsınız:

Outlook faylını korlanmadan qoruyun

Məlumdur ki, Outlook korrupsiyaya meyllidir. Buna görə də, Outlook formasının korrupsiyasından necə qorunacağımızı başa düşməliyik. Əvvəlcə virus hücumlarının qarşısını almaq üçün antivirus proqramı quraşdırmaq və heç vaxt naməlum qoşmanı yükləmək lazımdır. Bundan əlavə, biz kimi güclü təmir alətini əldə etməkdən daha yaxşı olarıq DataNumen Outlook RepairBu halda ən təsirli müalicə üsulunu təklif edə bilər. Outlook korrupsiyası.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc sql bərpa və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com