Outlook-da köhnəlmiş təqvim elementlərindən qoşmaları toplu şəkildə necə silmək olar

Outlook-da köhnə görüşlərdən və görüşlərdən qoşmaları silmək istəyirsinizsə, bu məqaləni oxuya bilərsiniz. Bunu bir anda necə həyata keçirəcəyinizi burada sizə təqdim edəcəyik.

Outlook faylınızın ölçüsünü azaltmaq üçün köhnə elementləri təmizləmək məsləhətdir. Bu, köhnə elementləri müntəzəm olaraq avtomatik olaraq silə bilən daxili "Avtomatik Arxiv" funksiyası ilə həyata keçirilə bilər. Bununla belə, bəzi istifadəçilər köhnə elementlərdəki qoşmaları elementlərin özlərinə təsir etmədən silmək istəyirlər. Aşağıda biz sizə köhnə təqvim elementlərindən qoşmaları toplu şəkildə silməyi öyrədəcəyik.

Köhnəlmiş Təqvim Elementlərindən Qoşmaları Toplu Silin

1. Başlamaq üçün "Alt + F11" ilə Outlook VBA redaktoruna daxil olun.
2. Sonra "Proqramlar üçün Microsoft Visual Basic" pəncərəsində VBA kodunu modula köçürün.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Daha sonra “OfOldCalendarItems BatchDelete Attachments” makrosuna klikləyin.
4. Nəhayət, bu makronu işə salmaq üçün “F5” düyməsini sıxın.
5. Makro tamamlandıqda, bütün Outlook təqvimlərinizi yoxlaya bilərsiniz.
6. Outlook 2 aydan çox köhnə təqvim elementlərinin bütün əlavələrini silməlidir.

Zərərli Outlook Faylları ilə mübarizə aparın

Heç Outlook korrupsiyası ilə qarşılaşmısınızmı? Adətən onu necə atırsınız? Daha tez-tez, ilk növbədə, gələnlər qutusu təmir alətini sınayacaqsınız - scanpst. Lakin, ciddi PST zədələnməsi halında, daxili yardım proqramı sizə kömək edə bilməz. Beləliklə, daha təcrübəli və diqqətəlayiq üçüncü tərəf alətini yaxınlıqda saxlamaq tövsiyə olunur, məsələn DataNumen Outlook Repair.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc sql təmiri və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com