Outlook-da Görüş Dəvətini Göndərməzdən əvvəl İştirakçıları Avtomatik Necə Saymaq olar

Bu məqalə sizə görüş dəvəti göndərməzdən əvvəl avtomatik olaraq iştirakçıların sayını əldə etmək üçün Outlook VBA-dan necə istifadə edəcəyinizi öyrədəcək. 

E-poçt göndərməzdən əvvəl alıcıları saymaq kimi, bəzi istifadəçilər də görüş dəvəti göndərməzdən əvvəl iştirakçıları saymaq istəyirlər. Həmişəki kimi, bu, təklif olunan görüşün ümumi dəyərini qiymətləndirmək və sonra iştirakçılara belə bir görüş dəvəti göndərib-göndərməmək barədə qərar vermək məqsədi daşıyır. Bundan əlavə, Outlook istifadəçilərə iştirakçıları tələb olunan və ya isteğe bağlı olaraq təyin etməyə imkan verdiyindən, bəziləri iştirakçıları müxtəlif növlərdə saymaq istəyirlər. Görüş resursları və müddəti daxil edilsəydi, daha yaxşı ola bilməzdi. Outlook-da belə bir birbaşa funksiya olmasa da, bunu həyata keçirmək üçün yenə də VBA kodundan istifadə edə bilərsiniz.

Görüş Dəvətini Göndərməzdən əvvəl İştirakçıları Avtomatik Sayın

1. Başlamaq üçün Outlook proqramınızı işə salın.
2. Sonra əsas Outlook pəncərəsində "Alt + F11" düymələri qısa yollarını basın.
3. Sonra Outlook VBA redaktoruna uğurla daxil olacaqsınız. İndi “ThisOutlookSession” layihəsini tapıb açmalısınız.
4. Sonradan, aşağıdakı VBA kodlarını bu layihəyə köçürün və yapışdırın.

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMeetingInvitation As Outlook.MeetingItem
    Dim objMeeting As Outlook.AppointmentItem
    Dim objAttendees As Outlook.Recipients
    Dim objAttendee As Outlook.recipient
    Dim lRequiredAttendeeCount, lOptionalAttendeeCount, lResourceCount As Long
    Dim strMsg As String
    Dim nPrompt As Integer
 
    If TypeOf Item Is MeetingItem Then
       Set objMeetingInvitation = Item
       Set objMeeting = objMeetingInvitation.GetAssociatedAppointment(True)
       Set objAttendees = objMeetingInvitation.Recipients
    End If
 
    lRequiredAttendeeCount = 0
    lOptionalAttendeeCount = 0
    lResourceCount = 0
 
    'Count the required & optional attendees and resources, etc.
    For Each objAttendee In objAttendees
         If objAttendee.Type = olRequired Then
            lRequiredAttendeeCount = lRequiredAttendeeCount + 1
         ElseIf objAttendee.Type = olOptional Then
            lOptionalAttendeeCount = lOptionalAttendeeCount + 1
         ElseIf objAttendee.Type = olResource Then
            lResourceCount = lResourceCount + 1
         End If
    Next
 
    'Double check the meeting invitation details
    strMsg = "Meeting Details:" & vbCrLf & vbCrLf & _
     "Required Attendees: " & lRequiredAttendeeCount & vbCrLf & _
     "Optional Attendees: " & lOptionalAttendeeCount & vbCrLf & _
     "Resources: " & lResourceCount & vbCrLf & _
     "Duration: " & GetDuration(objMeeting) & vbCrLf & vbCrLf & _
     "Are you sure to send this meeting invitation?"
 
    nPrompt = MsgBox(strMsg, vbExclamation + vbYesNo, "Double Check Meeting Invitation")
 
    If nPrompt = vbYes Then
       Cancel = False
    Else
       Cancel = True
    End If
End Sub

Function GetDuration(objCurMeeting As AppointmentItem) As String
    'Convert minute to hour
    If objCurMeeting.Duration > 60 Then
       GetDuration = Round(objCurMeeting.Duration / 60, 1) & " hours"
    ElseIf objCurMeeting.Duration = 60 Then
       GetDuration = Round(objCurMeeting.Duration / 60, 1) & " hour"
    ElseIf objCurMeeting.Duration < 60 Then
       GetDuration = objCurMeeting.Duration & " mins"
    End If
End Function

5. Bundan sonra bu kodu imzalamalısınız.
6. Daha sonra Outlook-un rəqəmsal imzalanmış makrolara icazə verdiyinə əmin olun.
7. Bundan sonra, hər dəfə görüş dəvətlərində “Göndər” düyməsini kliklədikdə, aşağıdakı şəkildəki kimi iştirakçıların sayını, resursları və müddəti göstərən mesaj alacaqsınız:

Əsəbiləşdirən Outlook Korrupsiyasının öhdəsindən çevik yanaşın

Yəqin ki, siz əvvəllər Outlook problemləri ilə qarşılaşmısınız, məsələn, donma, müxtəlif səhv mesajları və s. Xoşbəxtlikdən, Outlook əvvəlcədən quraşdırılmış bir gələn qutusu təmir aləti ilə gəlir scanpstkiçik məsələləri həll etməyə qadir olan. Ancaq problem ciddidirsə, daha çox ixtisaslaşmış bir vasitəyə müraciət etməlisiniz, məsələn DataNumen Outlook Repair.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc pozulmuş mdf və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com