Word Cədvəlinizdə Boş Sətir və Sütunları Silməyin 3 Sürətli Yolu

Bu yazıda sizə Word cədvəlinizdəki boş sətirləri və sütunları silməyin 3 sürətli yolunu izah edəcəyik.

Cədvəllər sənəd üçün, xüsusən də müxtəlif növ məlumatların saxlanması üçün vacibdir. Bəzən uzun bir cədvəl bir səhifəni keçə və bir neçə səhifəyə uzana bilər. Beləliklə, cədvəl uzun və mürəkkəb olduqda, onu sadələşdirmək üçün edə biləcəyiniz tədbirlər var. Məsələn, lazımsız boş sətir və sütunları silə bilərsiniz.

Aşağıda istifadə edə biləcəyiniz 3 üsul var.

Metod 1: Boş sətirləri və sütunları əl ilə silin

1. Əvvəlcə boş bir sətir və ya sütun seçin.
2. Sonra kontekst menyusunu əldə etmək üçün sağ klikləyin. Menyuda müvafiq olaraq "Sətrləri Sil" və ya "Sütunları Sil" seçin.

Təəssüf ki, siz bir neçə ardıcıl olmayan sətir və ya sütun seçə və bu yolla birlikdə silə bilməzsiniz. Bu tələb üçün əvvəlki məqaləmizə müraciət edə bilərsiniz: Word Cədvəlinizdə birdən çox sətir və ya sütunu toplu silmək üçün 5 sürətli üsul

Metod 2: Cədvəldəki bütün boş sətirləri və sütunları toplu silin

Metod 1 öz məhdudiyyətinə malikdir. Beləliklə, biz sizə VBA kodları vasitəsilə cədvəldəki sətir və sütunları toplu şəkildə silməyin yolunu təklif edəcəyik.

1. Başlamaq üçün kursoru hədəf cədvəlinin içinə qoyun.
2. İkincisi, “Alt+ F11” düyməsini basaraq VBA redaktorunu işə salın.
3. Redaktorda əvvəlcə “Normal” layihəsinə klikləyin.
4. Sonra menyu çubuğunda "Daxil et" sekmesini vurun.
5. Açılan menyuda "Modul" seçin.
6. Modulu açmaq üçün üzərinə iki dəfə klikləyin və aşağıdakı kodları ora yapışdırın:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Nəhayət, menyu çubuğundakı "Çalış" düyməsini basın və ya "F5" düyməsini basın.

Bir neçə saniyə ərzində həmin cədvəldəki bütün boş sətir və sütunları siləcəksiniz.

Metod 3: Sənəddəki bütün cədvəllərdəki bütün boş sətirləri və sütunları toplu silmək

1. Əvvəlcə makro qurmaq və işə salmaq üçün 2-ci üsuldakı addımları təkrarlayın.
2. Yalnız bu dəfə həmin makronu aşağıdakılarla əvəz edin:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Qırılmış Sənədi bərpa edin

Bu günlərdə itirilmiş məlumatları geri qaytarmağın birdən çox yolu var. Məsələn, ehtiyat nüsxələrinə müraciət etmək həmişə sizin əsas prioritetiniz olaraq qalır. Əgər bu, ən son məlumatları geri almaq ehtiyacınızı ödəmirsə, onda bir cəhd edə bilərsiniz doc təmir aracı.

Müəllif Giriş:

Vera Çen məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc xlsx təmiri və pdf proqram məhsullarının təmiri. Ətraflı məlumat üçün ziyarət edin www.datanumen.com