Excel İş Vərəqində Seçilmiş Hüceyrələri Outlook E-poçtu kimi Tez Göndərmək üçün 2 Metod

Bəzən Excel iş vərəqində seçilmiş xanaları tez bir zamanda Outlook e-poçtuna daxil etmək və bu e-poçtu göndərmək istəyə bilərsiniz. Bu yazı sizə 2 üsul təklif etmək istəyinə baxacaq.

Əvvəlki məqaləm “Excel İş Vərəqini Outlook E-poçtu kimi Göndərməyin 2 Sürətli Metodları” sizə bütün Excel iş vərəqini e-poçt kimi göndərməyi öyrətdi. Bununla belə, bəzən iş vərəqində seçilmiş hüceyrələri yalnız e-poçt kimi göndərmək istərdiniz. Bu tələbə cavab olaraq burada sizə 2 üsul təqdim edəcəyik. İstədiyiniz kimi seçim edə bilərsiniz.

Metod 1: Seçilmiş xanaları əl ilə e-poçta köçürün

1. Başlamaq üçün mənbə Excel faylını açın və düzgün Excel iş səhifəsinə daxil olun.
2. Sonra Outlook e-poçtu kimi göndərmək istədiyiniz hüceyrələri seçin.
3. Sonra seçilmiş hüceyrələri kopyalamaq üçün "Ctrl + C" düymələri qısa yollarını basın.
4. Bundan sonra Outlook proqramını işə salın.
5. Sonra, yeni Outlook e-poçtu yaratmaq üçün "Ev" lentindəki "Yeni E-poçt" düyməsini klikləyin.
6. Daha sonra yeni Mesaj pəncərəsində mesajın əsas hissəsinə klikləyin.
7. Və sonra əvvəlcədən kopyalanmış seçilmiş Excel hüceyrələrini yapışdırmaq üçün "Ctrl + V" düymələrini basın.
8. Nəhayət, siz həmişəki kimi e-poçtu tərtib edə və onu göndərmək üçün “Göndər” düyməsini klikləyə bilərsiniz.

Metod 2: Seçilmiş xanaları VBA vasitəsilə e-poçt kimi göndərin

1. Ən başlanğıcda mənbə Excel iş kitabını açın.
2. Sonra Excel VBA redaktoruna daxil olmaq üçün "Alt + F11" düymələrini basın.
3. Yeni pəncərədə yeni modul daxil etmək üçün "Daxil et" > "Modul" düyməsini basın.
4. Növbəti addım Microsoft Outlook Obyektini aktivləşdirməkdir. “Alətlər” > “İstinadlar” bölməsinə klikləyin. Açılan informasiya qutusunda “Microsoft Outlook Obyekt Kitabxanası”nı tapın və işarələyin.
5. Sonradan aşağıdakı VBA kodunu bu modula köçürün.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Nəhayət, bir cəhd edə bilərsiniz.

• Birincisi, hər zamanki kimi xüsusi hüceyrələri seçin.
• Sonra yeni makroya qayıdın və onu işə salmaq üçün F5 düyməsini basın.
• Dərhal yeni bir Outlook e-poçtu görünəcək, burada seçilmiş hüceyrələrin aşağıdakı ekran görüntüsü kimi e-poçt gövdəsinə daxil edildiyini görə bilərsiniz:

PST faylı Excel faylı ilə eyni həssasdır

Bildiyimiz kimi, Excel faylı və Word sənədi korlanmaya meyllidir. Əslində, eyni şey Outlook poçt qutunuzdakı bütün elementləri ehtiva edən PST faylı üçün də keçərlidir. Beləliklə, PST məlumatlarınızın təhlükəsizliyini təmin etmək çətin bir işdir. Ən təsirli tədbirlərdən biri faylın müntəzəm olaraq ehtiyat nüsxəsini çıxarmaqdır. Üstəlik, dərhal xilasetməni təmin etmək üçün təcrübəli bir vasitə hazırlamalısınız, məsələn DataNumen Outlook Repair, bacarır Outlook-u bərpa edin tər tökmədən məlumat.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc təmir mdf və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com