Word sənədinizdən bölmələri çıxarmağın 2 sürətli yolu

Bu yazıda biz sizə Word sənədinizdən bölmələri digərinə və ya bir neçəsinə çıxarmağın 2 sürətli və asan yolunu təklif edəcəyik.

Məzmunu bir sənəddən digərinə çıxarmaq çox vaxt olur. Və əvvəlki məqaləmizdə sənəddən səhifələrin necə çıxarılacağını müzakirə etdik. Ətraflı məlumat üçün bu məqaləyə müraciət edə bilərsiniz: Word sənədinizdən fərdi səhifələri çıxarmağın 2 sürətli yolu

Bu gün sizə bölmə üzrə necə çıxarmağı göstərəcəyik.    

Metod 1: Cari Bölməni Yeni Sənədə çıxarın

1. Əvvəlcə kursoru hədəf bölməsinə yerləşdirin.
2. Sonra Word-də VBA redaktorunu işə salmaq üçün “Alt+ F11” düyməsini basın.
3. Sonra sol sütunda "Normal" düyməsini basın.
4. Və menyu çubuğunda "Daxil et" düyməsini basın.
5. Sonra açılan menyuda "Modul" seçin.
6. Yeni modulu açmaq üçün iki dəfə klikləyin və aşağıdakı kodları ora yapışdırın:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Sonra, menyu çubuğunda "Çalış" düyməsini basın və ya "F5" düyməsini basın.
8. Sonra "Gözdən keçir" pəncərəsi açılacaq. Yeni sənədin saxlanacağı yeri seçin və "OK" düyməsini basın.
9. Və "Fayl adı" qutusuna yeni faylın adını daxil edin və "OK" düyməsini basın.

İndi siz bölməni yeni sənədə çıxartdınız.

Metod 2: Sənəddəki Hər Bölməni ayrı-ayrılıqda yenilərinə çıxarın

Bu üsul sizə sənəddəki bütün bölmələri toplu şəkildə emal etməyə kömək edə bilər. Təbii ki, bizə də makro lazımdır.

1. Başlamaq üçün hədəf sənədini açın.
2. Sonra makronu quraşdırmaq və işə salmaq üçün 1-ci üsuldakı addımları izləyin.
3. Yalnız bu dəfə həmin makronu bununla əvəz edin:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Yenə də "Gözdən keçir" pəncərəsində saxlama yolunu seçin və "OK" düyməsini basın.

Qıcıqlandırıcı söz səhvlərini düzəldin

Onu istifadə edərkən bəzi Word xətalarına rast gəlmək adi haldır. Bu bezdirici ola bilər, buna vaxt ayırmalıyıq sözü bərpa edin mümkün olduğu qədər tez. Çünki onu nə qədər gecikdirsək, məlumat itkisi bir o qədər ağır ola bilər. Buna görə də, əvvəlcədən təmir xidmətini əldə etmək tövsiyə olunur.

Müəllif Giriş:

Vera Çen məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc xarab xls və pdf proqram məhsullarının təmiri. Ətraflı məlumat üçün ziyarət edin www.datanumen.com