如何通過VBA將Outlook中的所有表快速導出到Excel工作簿

Outlook解決方案 2025 年 9 月 29 日

如果要快速將表從Outlook電子郵件導出到Excel文件，可以利用本文介紹的方法。它將使用VBA只需單擊一下即可幫助您實現這一目標。

眾所周知，Excel專為表和數據統計而設計。因此，當您收到一封電子郵件，其中包含正文中的多個表時，您可能希望將所有這些表導出到Excel文件中，以便更好地分析表中的數據。因此，這裡我們將教您如何快速將所有表從電子郵件導出到新的Excel工作簿。現在，請繼續閱讀以獲取VBA代碼和詳細步驟。

將所有表從Outlook電子郵件導出到Excel工作簿

首先，像往常一樣啟動 Outlook 應用程式。
然後在Outlook主窗口中，按“ Alt + F11”鍵按鈕。
接下來，在下面的“ Microsoft Visual Basic for Applications”窗口中，您應該打開一個空模塊。
隨後，您需要將下面的VBA代碼複製到該模塊中。

Sub ExportTablesinEmailtoExcel()
    Dim objMail As Outlook.MailItem
    Dim objWordDocument As Word.Document
    Dim objTable As Word.Table
    Dim lTableCount As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim i As Long
 
    'Create a new excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    'Get the table(s) in the selected email
    Set objMail = Outlook.Application.ActiveExplorer.Selection.item(1)
    Set objWordDocument = objMail.GetInspector.WordEditor
    lTableCount = objWordDocument.Tables.Count
 
 
    If lTableCount > 1 Then
       'If there is more than one table
       'Copy each table into separate worksheet
       For i = 1 To lTableCount
           Set objTable = objWordDocument.Tables(i)
           objTable.Range.Copy
 
           Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           objExcelWorksheet.Paste
           objExcelWorksheet.Columns.AutoFit
       Next
    Else
      'If there is only one table
      'Just copy it into the first worksheet
      Set objTable = objWordDocument.Tables(1)
      objTable.Range.Copy
 
      Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
      objExcelWorksheet.Paste
      objExcelWorksheet.Columns.AutoFit
    End If
End Sub