如何快速將Word文檔的特定頁面附加到Outlook電子郵件

Outlook解決方案 2025 年 9 月 29 日

MS Word有一個直接功能，支持用戶將當前的Word文檔作為電子郵件附件發送。但有時，您可能只希望將 Word 文檔的特定頁面附加到 Outlook 電子郵件中。現在，本文將向您分享一個方法。

要在 MS Word 應用程序中將整個 Word 文檔作為電子郵件附件發送，您只需轉到“文件”菜單，然後轉到“保存並發送”選項卡，在該選項卡下您可以找到“作為附件發送”按鈕。然而，有時您想要發送的內容可能只是文檔的特定頁面。這種情況，可以使用下面介紹的方法來完成。

將 Word 文檔的特定頁面附加到電子郵件

首先，您應該打開要通過電子郵件發送其特定頁面的源 Word 文檔。
然後，進入MS Word窗口後，您需要按“Alt + F11”鍵按鈕。
接下來，您將可以訪問 MS Word 中的 VBA 編輯器。
之後，您需要啟用「Microsoft Outlook 物件庫」。您可以點擊“工具”>“引用”來完成此操作。
隨後，您應該將以下 VBA 代碼複製到未使用的模塊中。

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

最後，你可以運行這個宏。只需按 F5 鍵按鈕或點擊工具欄中的“運行”圖標即可。
宏完成後，將顯示一封新的 Outlook 電子郵件，其中附有源 Word 文檔的摘錄，如以下屏幕截圖所示：

從損壞的 Outlook 文件中提取最大數據

如果您已經使用 Outlook 數十年，您可能遇到過各種 Outlook 問題，包括彈出內部錯誤消息、突然崩潰以及嚴重的文件損壞。由於以下事實：掃描儀，內置修復工具，只能處理小問題，你最好隨身攜帶一個外部強大的修復工具，比如 DataNumen Outlook Repair。它能夠從損壞的 Outlook 數據文件中提取最大數據。

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 SQL修復和Outlook修復軟件產品。欲了解更多信息，請訪問萬維網。datanumen.COM