如何為不同顏色類別的 Outlook 會議自動設置不同的提醒時間

如果您正在按顏色類別對 Outlook 會議進行分類，並希望為不同顏色類別的會議設置不同的提醒時間，您可以參考這篇文章。 下面教大家用Outlook VBA來實現。

例如，您將會議分為兩組。一組歸為「異地」類別，因為會議地點較遠；另一組歸為「本地」類別，因為會議地點就在附近。現在，您希望 Outlook 能自動將「異地」會議的提醒時間設定為開始前 1 小時，「本地」會議的提醒時間設定為開始前 15 分鐘。針對這項需求，我們將在下文中分享一種快速方法。

自動為不同顏色類別的會議設置不同的提醒

1. 首先，啟動Outlook應用程序。
2. 然後，按“Alt + F11”鍵按鈕訪問 VBA 編輯器窗口。
3. 接下來，在隨後的窗口中，將下面的 VBA 代碼複製並粘貼到“ThisOutlookSession”項目中。

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. 之後，您需要點擊進入“Application_Startup”子程序，然後按“F5”鍵來執行此巨集。
5. 此後，每次將新會議添加到默認日曆或更改現有會議時，Outlook 都會自動檢查會議類別並自動設置不同的提醒時間。

消除Outlook錯誤

Outlook 可能會不時出現各種問題。因此，使用者學習如何應對 Outlook 問題至關重要。首先，最好定期備份 Outlook 資料。此外，如果經濟條件允許，建議保留一個強大的備份檔案。 Outlook修復 附近的工具，例如 DataNumen Outlook Repair. 它可以掃描您的 PST 文件以找出 Outlook 問題，然後輕鬆解決它們。

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 sql恢復 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM