如何在Outlook中自動移動具有特定抄送收件人的電子郵件

Outlook解決方案 2025 年 9 月 29 日
立即分享：

實際上，大多數人可能都希望建立一個 Outlook 規則，自動移動包含特定副本收件者的電子郵件。但是 Outlook 規則不支援檢查抄送收件者。因此，本文將教您如何使用 Outlook VBA 實作此功能。

顯然，您無法創建Outlook規則來搜索特定抄送收件人。 如以下屏幕截圖所示，對​​於收到的電子郵件，您只能檢查自己的姓名是否在抄送框中。 同樣，對於已發送的電子郵件，即使沒有規則條件也要選中“抄送”框。沒有條件尋找CC收件人

因此，如果要將Outlook配置為自動移動具有特定抄送收件人的電子郵件，則必須尋求其他方法。 然後。 在這裡，我們將教您如何通過Outlook VBA實現它。

自動移動具有特定抄送收件人的已發送電子郵件

  1. 首先，轉到“開發人員”選項卡，然後單擊“ Visual Basic”按鈕。
  2. 然後打開“ ThisOutlookSession”項目，並將以下VBA代碼複製到其中。
Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

自動移動具有特定抄送收件人的已發送電子郵件

  1. 隨後，您應該繼續對此代碼簽名並照常更改宏設置。
  2. 最後，您可以退出“ Visual Basic”窗口。 此後，具有特定抄送收件人的電子郵件將被移動到指定的郵件文件夾。

自動移動具有特定抄送收件人的已接收電子郵件

現在，上面的VBA代碼旨在與特定的CC收件人一起移動已發送的電子郵件，如果要在接收的電子郵件中查找特定的CC收件人然後進行移動，則應改用以下代碼。

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

自動移動具有特定抄送收件人的已接收電子郵件

為Outlook腐敗做好充分準備

儘管Outlook具有豐富的功能，但仍然無法倖免於腐敗。 因此，您應該對所有潛在風險保持警惕。 毫無疑問，關鍵步驟必須是對Outlook數據進行一致且最新的備份。 此外，您應保持 損壞的Outlook恢復工具 在附近。 如果備份和Scanpst.exe都失敗，它將很方便。

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 修復 SQL Server mdf文件錯誤 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM

立即分享：

評論被關閉。