如何自動禁用來自未知發件人的傳入Outlook電子郵件中的超鏈接

Outlook解決方案 2025 年 9 月 29 日

為了阻止惡意鏈接，最好將Outlook配置為自動禁用來自未知發件人的傳入電子郵件中的超鏈接。本文將揭示一段VBA代碼，可以幫助您像軟木塞一樣獲得它。

許多用戶抱怨電子郵件中的病毒攻擊了他們的Outlook文件。通常是因為他們很容易信任來自未知發件人的那些電子郵件。因此，他們下載或單擊郵件中的超鏈接。現在，在下文中，我們將分享一種方法。它能夠讓Outlook自動禁用來自未知發件人的傳入電子郵件的超鏈接。如果您有此類需求，請繼續閱讀以獲取更多詳細信息。

自動禁用來自未知發件人的傳入電子郵件中的超鏈接

首先，在 Outlook 中，按下「Alt + F11」進入 VBA 編輯器。
接下來，在新畫面中，請依照文章「」中的說明新增「MS VBScript 正規表示式」物件。如何在 VBA 中新增物件庫引用“。
然後，將以下代碼複製並粘貼到“ ThisOutlookSession”項目中。

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

之後，可以透過重新啟動 Outlook 或在「Application_Startup」子程式中按下「F5」鍵來啟動此巨集。
從那時起，每當發自發件人的，未存儲在默認聯繫人文件夾中的電子郵件進入收件箱時，Outlook都會自動禁用其中的超鏈接。

Outlook保護中的幾個必要事項

由於Outlook容易受到損壞，因此保護Outlook文件非常困難。在這裡，我們將列出Outlook數據保護期間的一些必備條件。首先，您必須定期備份Outlook數據。此外，您必須提防所有潛在風險，例如惡意附件或超鏈接。最後但並非最不重要的一點是，您應該預先準備一個功能強大的Outlook修復工具，例如 DataNumen Outlook Repair。當您需要時，它一定會派上用場維修PST 文件，但收件箱修復工具證明失敗。

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括損壞的MDF 和Outlook修復軟件產品。欲了解更多信息，請訪問萬維網。datanumen.COM