2種在Outlook中按發件人快速計數電子郵件的方法

Outlook解決方案 2025 年 9 月 29 日
立即分享：

如果要按發件人計數電子郵件，可以參考本文。 在這裡，我們將向您介紹2種快速方法。

為了找出最活躍的寄件人，您可能需要統計每個寄件者的郵件數量。雖然 Outlook 沒有提供直接的統計功能，但您仍然可以嘗試一些方法，例如以下方法一。如果您覺得方法一過於繁瑣，可以選擇方法二。方法二更有效率，它使用 VBA 快速統計每個寄件者的郵件數量，並將統計結果匯出到 Excel。接下來，我們將詳細介紹這兩種方法。這裡，我們將以收件匣中的郵件為例來說明。

方法1：按“發件人”字段對項目進行分組後獲取計數

  1. 首先，啟動Outlook應用程序。
  2. 然後，打開收件箱文件夾。
  3. 接下來，切換到“查看”標籤。
  4. 隨後，在“排列”組中選擇“來自”。按“發件人”排列收件箱項目
  5. 一次，所有收件箱項已根據不同的發件人分為不同的組。
  6. 現在，要計算來自特定發件人的項目，您可以選擇相關組中的所有項目，然後按“ Enter”鍵。 在彈出警告中，您可以看到計數。獲取警告中的項目計數

這意味著非常容易，但是項目計數實際上包括其他類型的項目，例如會議邀請，任務請求和收據，而不僅僅是電子郵件計數。 因此，如果您只想計算電子郵件，則可以使用以下方式。

方法2：使用Outlook VBA按發件人計數電子郵件

  1. 首先，在 Outlook 中按下「Alt + F11」鍵。
  2. 然後，根據“啟用“MS Excel 物件庫”的說明啟用“如何在 VBA 中新增物件庫引用“。
  3. 接下來，將下面的代碼複製到一個未使用的模塊中。
Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

VBA代碼-按發件人計數收件箱電子郵件

  1. 之後，按“ F5”鍵按鈕。
  2. 宏完成後，將顯示一個新的Excel文件。
  3. 如您所見，它包含來自不同發件人的收件箱電子郵件的計數。Excel中的電子郵件計數

處理令人沮喪的Outlook問題

也許您的Outlook曾經遇到過許多問題。 為了有效地解決這些問題，您可能渴望一種通用而強大的方法。 但是，實際上，沒有這種方法。 您可以做的是當心自己在Outlook中的操作並進行定期備份。 當然，如果可能的話，我們建議您最好隨身攜帶一個經驗豐富的修復工具，例如 DataNumen Outlook Repair。 它可以修復各種PST問題並進行修復 損壞的PST 文件像微風一樣。

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 恢復 Sql Server 和Outlook修復軟件產品。 欲了解更多信息，請訪問 萬維網。datanumen.COM

立即分享：

評論被關閉。