Cách in nhanh tất cả tệp đính kèm hình ảnh của email Outlook chỉ trên một trang

giải pháp triển vọng Tháng Chín 29, 2025

Để tiết kiệm giấy và mực máy in, một số người dùng chỉ muốn in tất cả các hình ảnh đính kèm trong email trên một trang, thay vì một hình ảnh trên mỗi trang. Bây giờ, bài viết này sẽ chia sẻ một phương tiện để nhận ra nó.

Như chúng ta đã biết, việc in ảnh khá tốn mực máy in. Vì vậy, để tiết kiệm giấy và mực máy in, có thể bạn thích in nhiều tệp đính kèm hình ảnh trên cùng một trang thay vì in ảnh trên các trang riêng biệt. Mặc dù Outlook không cung cấp tính năng như vậy nhưng bạn vẫn có thể đạt được tính năng này bằng các cách sau.

Chỉ in tất cả tệp đính kèm hình ảnh của email Outlook trên một trang

Để start bằng, khởi chạy ứng dụng Outlook của bạn.
Sau đó, trong cửa sổ Outlook, hãy nhấn vào các nút phím “Alt + F11”.
Tiếp theo, bạn sẽ vào cửa sổ “Microsoft Visual Basic for Applications”, trong đó trước tiên bạn phải kích hoạt “Microsoft Word Object Library ”.
Sau đó, bạn cần mở một mô-đun không được sử dụng.
Sau đó, sao chép và dán mã VBA sau vào mô-đun này.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

Sau đó, bạn có thể quay lại danh sách email. Chọn hoặc mở email có tệp đính kèm ảnh mà bạn muốn in ra.
Sau đó, kích hoạt macro này. Trong cửa sổ macro hiện tại, chỉ cần nhấn phím “F5” hoặc nhấp vào biểu tượng “Chạy” trên thanh công cụ.
Cuối cùng, khi macro chạy xong, tất cả tệp đính kèm hình ảnh của email nguồn sẽ được in ra trên một trang, giống như ảnh chụp màn hình sau:

Xử lý tệp Outlook bị hỏng

Với ngày càng nhiều dữ liệu được lưu trữ trong Outlook của bạn, tệp Outlook của bạn ngày càng dễ bị tấn công. Nó có thể bị tổn hại do nhiều yếu tố bên trong và bên ngoài. Ngoài ra, rất khó để dự đoán tham nhũng Outlook. Vì vậy, những gì bạn có thể làm là đảm bảo giải cứu ngay lập tức và hiệu quả khi gặp lỗi Outlook. Ví dụ, bạn phải giữ một chuyên ngành PST sửa chữa công cụ, như DataNumen Outlook Repair trong vùng lân cận. Nó sẽ quét và khôi phục các tệp bị hỏng một cách dễ dàng.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm lấy lại Sql Server và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm