Cách xuất nhanh tất cả các siêu liên kết trong nhiều email Outlook sang Excel

Khi cần trích xuất tất cả các siêu liên kết trong một hoặc nhiều email, việc sao chép từng liên kết một là không hiệu quả. Bài viết này sẽ hướng dẫn bạn phương pháp xuất nhanh tất cả các siêu liên kết trong nhiều email sang Excel.

Vì một số lý do, chẳng hạn như ghi lại các siêu liên kết trong tất cả các email đã gửi của bạn, bạn sẽ cần trích xuất các siêu liên kết đó. Không nghi ngờ gì nữa, bạn không nên trích xuất và sao chép chúng theo cách thủ công. Bạn phải mong đợi một cách tiếp cận thông minh hơn nhiều, chẳng hạn như sử dụng VBA. Ở đây chúng tôi sẽ chia sẻ cho bạn một đoạn mã VBA như vậy, có thể xuất tất cả các siêu liên kết trong nhiều email sang Excel chỉ bằng một cú nhấp chuột dễ dàng.

Xuất tất cả các siêu liên kết trong nhiều email sang Excel

1. Trước tiên, hãy mở chương trình Outlook như bình thường.
2. Sau đó, trong cửa sổ Outlook, bạn cần nhấn các nút phím “Alt + F11”.
3. Ngay lập tức, bạn sẽ có quyền truy cập vào trình soạn thảo Outlook VBA.
4. Tiếp theo, bạn cần kích hoạt “Thư viện đối tượng Microsoft Word” cũng như “Thư viện đối tượng Microsoft Excel”. Nhấp vào “Công cụ” > “Tham chiếu” rồi kích hoạt chúng trong hộp thoại bật lên.
5. Tiếp theo, bạn cần mở một mô-đun không sử dụng, trong đó bạn phải sao chép mã VBA bên dưới vào mô-đun này.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Sau đó, bạn có thể thoát khỏi cửa sổ soạn thảo VBA hiện tại.
7. Sau đó, truy cập “Tùy chọn Outlook” để tùy chỉnh Thanh công cụ truy cập nhanh để thêm macro mới được thêm vào Thanh công cụ truy cập nhanh.
8. Cuối cùng, bạn có thể chụp:

• Trước hết, trong danh sách email, hãy chọn những email có siêu liên kết mà bạn muốn trích xuất.
• Sau đó, nhấp vào nút macro trong Thanh công cụ truy cập nhanh.
• Khi macro kết thúc, bạn sẽ nhận được một tệp Excel, giống như hình dưới đây:

Khắc phục sự cố Outlook không mong muốn

Các sự cố với Outlook có thể xảy ra bất ngờ mà không báo trước. Tuy nhiên, đối với các lỗi nhỏ, Outlook có thể tự khắc phục bằng cách khởi động lại hoặc sử dụng các công cụ hỗ trợ đơn giản. công cụ sửa chữa hộp thư đến. Nhưng nếu gặp một số rắc rối nghiêm trọng, các phương tiện bên trong sẽ không phát huy tác dụng. Tại thời điểm này, giải pháp cuối cùng của bạn chắc chắn là một công cụ mạnh mẽ và uy tín hơn, chẳng hạn như DataNumen Outlook Repair.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm mdf bị hỏng và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm