MS Word có tính năng trực tiếp hỗ trợ người dùng gửi tài liệu Word hiện tại dưới dạng tệp đính kèm email. Nhưng đôi khi, bạn chỉ có thể hy vọng đính kèm các trang cụ thể của tài liệu Word vào email Outlook. Bây giờ, bài viết này sẽ chia sẻ cho bạn một phương pháp.
Để gửi toàn bộ tài liệu Word dưới dạng tệp đính kèm email trong ứng dụng MS Word, bạn chỉ cần vào menu “Tệp” và chuyển sang tab “Lưu & Gửi”, trong đó bạn có thể tìm thấy nút “Gửi dưới dạng tệp đính kèm”. Tuy nhiên, đôi khi, những gì bạn muốn gửi có thể chỉ là các trang cụ thể của tài liệu. Trong tình huống này, bạn có thể sử dụng phương pháp được giới thiệu sau đây để thực hiện.
Đính kèm các trang cụ thể của tài liệu Word vào email
- Trước hết, bạn nên mở tài liệu Word nguồn có các trang cụ thể mà bạn muốn gửi qua email.
- Sau đó, sau khi vào cửa sổ MS Word, bạn cần nhấn các nút phím “Alt + F11”.
- Tiếp theo, bạn sẽ có quyền truy cập vào trình soạn thảo VBA trong MS Word.
- Sau đó, bạn cần kích hoạt “Thư viện đối tượng Microsoft Outlook”. Bạn có thể nhấn vào “Công cụ” > “Tham chiếu” để thực hiện việc này.
- Sau đó, bạn nên sao chép mã VBA sau vào một mô-đun không được sử dụng.
Sub AttachSpecificPagesToOutlookEmail()
Dim strDocumentName As String
Dim objSelectedPages As Word.Range
Dim objTempDocument As Word.Document
Dim objTempRange As Word.Range
Dim i As Long
Dim strTempDocument As String
Dim objOutlookApp As Outlook.Application
Dim objMail As Outlook.MailItem
strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
'Copy the contents from Page 2 to 4
'You can change the page as per your own needs
Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
Set objSelectedPages = Selection.Range
Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
objSelectedPages.Select
objSelectedPages.Copy
'Paste the copied contents into a new Word Document
Set objTempDocument = Word.Application.Documents.Add
objTempDocument.Activate
Set objTempRange = objTempDocument.Range(0, 0)
objTempRange.PasteAndFormat (wdFormatOriginalFormatting)
For i = objTempDocument.Paragraphs.Count To 1 Step -1
If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
objTempDocument.Paragraphs(i).Range.Delete
Else
Exit For
End If
Next i
'Save this document
strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
'Attach the new document to a new Outlook email
On Error Resume Next
Set objOutlookApp = GetObject(, "Outlook.Application")
If objOutlookApp Is Nothing Then
Set objOutlookApp = CreateObject("Outlook.Application")
End If
Set objMail = objOutlookApp.CreateItem(olMailItem)
objMail.Attachments.Add (strTempDocument)
objMail.Display
objTempDocument.Close False
Kill strTempDocument
End Sub
- Cuối cùng, bạn có thể chạy macro này. Chỉ cần nhấn nút phím F5 hoặc nhấn vào biểu tượng “Chạy” trên thanh công cụ.
- Sau khi macro kết thúc, một email Outlook mới sẽ hiển thị, được đính kèm với một đoạn trích của tài liệu Word nguồn, giống như ảnh chụp màn hình sau:
Trích xuất dữ liệu tối đa từ tệp Outlook bị hỏng
Nếu bạn đã sử dụng Outlook trong nhiều thập kỷ, bạn có thể đã phải đối mặt với nhiều vấn đề khác nhau về Outlook, bao gồm các thông báo lỗi bên trong cửa sổ bật lên, sự cố đột ngột cũng như tệp bị hỏng nghiêm trọng. Do thực tế là scanpst, công cụ sửa chữa sẵn có, chỉ có thể giải quyết các sự cố nhỏ, tốt hơn hết bạn nên mang theo một công cụ sửa lỗi mạnh mẽ bên ngoài, chẳng hạn DataNumen Outlook Repair. Nó có thể rút ra dữ liệu tối đa từ tệp dữ liệu Outlook bị hỏng.
Giới thiệu tác giả:
Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm sửa lỗi sql và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm