Cách trích xuất nhanh chóng tất cả người nhận từ nhiều tệp tin nhắn Outlook (.msg)

Một số người dùng muốn nhanh chóng trích xuất tất cả người nhận từ nhiều tệp thư Outlook được lưu từ email Outlook. Bây giờ, p nàyost sẽ xem xét điều này để chia sẻ một cách tiếp cận nhanh chóng.

Để trích xuất người nhận từ một tệp tin Outlook duy nhất, bạn chỉ cần nhấp đúp để mở tệp đó rồi sao chép người nhận trong cửa sổ Tin nhắn đã mở. Tuy nhiên, nếu bạn cần xử lý một loạt tệp thư Outlook thì phương pháp thủ công không đủ hiệu quả. Vì vậy, bạn có thể tìm kiếm một cách hiệu quả hơn nhiều. Ở đây chúng tôi sẽ giới thiệu một cái như vậy cho bạn. Đọc tiếp để biết chi tiết của nó.

Trích xuất tất cả người nhận từ nhiều tệp tin nhắn Outlook (.msg)

1. Đối với nhưtart, hãy truy cập vào trình soạn thảo Outlook VBA theo “Cách chạy mã VBA trong Outlook của bạn".
2. Tiếp theo, sao chép và dán mã VBA sau vào một mô-đun trống.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Sau đó, di chuyển con trỏ trong chương trình con đầu tiên.
4. Sau đó, nhấp vào nút “Run” hoặc nhấn phím “F5”.
5. Sau đó, trong hộp thoại bật lên, hãy chọn thư mục Windows chứa tệp thông báo Outlook (.msg) nguồn.
6. Sau khi chọn xong nhấn “OK” để macro tiếp tục chạy.
7. Khi macro kết thúc, một thông báo liệt kê tất cả địa chỉ email của người nhận được trích xuất sẽ hiển thị, như minh họa trong ảnh chụp màn hình sau.

Bảo vệ dữ liệu Outlook của bạn khỏi nguy hiểm

Dữ liệu Outlook được thừa nhận là dễ bị hỏng. Do đó, việc bảo vệ dữ liệu Outlook là một nhiệm vụ khá khó khăn. Nó đòi hỏi bạn phải kiên trì trong việc sao lưu thường xuyên dữ liệu Outlook. Ngoài ra, nếu có thể, nên thận trọng và nên chuẩn bị một Triển vọng có kinh nghiệm và chuyên nghiệp. PST sửa chữa công cụ, như DataNumen Outlook Repair, để bạn có thể được giải cứu ngay lập tức và kịp thời trong trường hợp Outlook bị hỏng.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm lấy lại Sql Server và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm