Cách tự động đánh dấu các cuộc hẹn cuối tuần là riêng tư trong Outlook

Hình thứcost người dùng, các cuộc hẹn đã lên lịch vào cuối tuần thường là riêng tư. Do đó, họ muốn Outlook tự động đánh dấu và hiển thị các cuộc hẹn đó ở chế độ riêng tư. Trong bài viết này, chúng tôi sẽ biến điều này thành hiện thực bằng một chút kịch bản.

Để phân biệt giữa cuộc hẹn công việc và cuộc hẹn riêng tư dễ dàng hơn, Outlook cho phép người dùng đánh dấu cuộc hẹn là riêng tư. Bằng cách này, bạn sẽ thấy việc in lịch khá tiện lợi và dễ dàng mà không cần phải hẹn lịch riêng. Trong trường hợp này, bạn có thể muốn Outlook của mình tự động nhận dạng và đánh dấu các cuộc hẹn cụ thể là riêng tư. Ví dụ: nhìn chung, các cuộc hẹn vào cuối tuần đều ở chế độ riêng tư, do đó bạn muốn để Outlook tự động đánh dấu chúng là riêng tư. Sau đó chúng tôi sẽ hướng dẫn bạn đạt được điều đó.

Tự động đánh dấu các cuộc hẹn cuối tuần là riêng tư

1. Đầu tiên, hãy khởi chạy trình soạn thảo Outlook VBA theo “Cách chạy mã VBA trong Outlook của bạn".
2. Sau đó, trong cửa sổ “Microsoft Visual Basic for Application”, hãy đặt đoạn mã sau vào dự án “ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

3. Sau đó, restart Outlook để kích hoạt macro.
4. Từ giờ trở đi, mỗi khi bạn tạo cuộc hẹn mới hoặc thay đổi cuộc hẹn hiện có sang cuối tuần, Outlook sẽ tự động đánh dấu cuộc hẹn đó là riêng tư.

Giải quyết các vấn đề khó chịu về Outlook

Có thể bạn đã gặp phải một số vấn đề khi xử lý Outlook, chẳng hạn như ứng dụng bị treo không mong muốn, thông báo lỗi bật lên, v.v. Khi đau khổ chúng, bạn sẽ lo lắng. Hãy bình tĩnh! Hoảng loạn chẳng giúp được gì mà còn khiến tình hình trở nên trầm trọng hơn. Trước hết, bạn có thể kiểm tra xem bạn có thể truy cập tệp PST như bình thường hay không. Nếu vậy, bạn phải sửa tệp PST, việc này có thể được thực hiện thông qua công cụ sửa chữa hộp thư đến hoặc một công cụ bên ngoài mạnh mẽ hơn, như DataNumen Outlook Repair.

Giới thiệu tác giả:

Shirley Zhang là một chuyên gia phục hồi dữ liệu trong DataNumen, Inc., công ty hàng đầu thế giới về công nghệ khôi phục dữ liệu, bao gồm sửa chữa mdf và các sản phẩm phần mềm sửa chữa triển vọng. Để biết thêm thông tin, hãy truy cập www.datanumennăm