Як швидко експортувати статистику голосування з електронної пошти Outlook на аркуш Excel

Якщо ви надіслали електронного листа з кнопками голосування, після того, як одержувачі надішлють вам свої відповіді, ви можете підрахувати та експортувати статистику голосування в аркуш Excel. Тож у цій публікації ми навчимо вас, як швидко цього досягти.

Outlook настільки потужний, що навіть пропонує функцію "Голосування". Моя попередня стаття “Уміле використання MS Outlook для голосування«навчив, як ефективно використовувати його. Також, здебільшого, після голосування, ви можете експортувати статистику голосування в аркуш Excel з певних причин, наприклад, щоб роздрукувати статистику. Але Outlook не підтримує цю функцію за замовчуванням. Тому далі ми навчимо вас, як це зробити, як пробку.

Експортуйте статистику голосування електронною поштою до аркуша Excel

1. З самого початку запустіть програму Outlook.
2. Потім слід натиснути кнопки Alt + F11 у головному вікні Outlook.
3. Далі у вікні «Microsoft Visual Basic for Applications» слід увімкнути «Бібліотеку об’єктів Microsoft Excel». Натисніть «Інструменти» > «Довідка». Потім у спливаючому діалоговому вікні поставте прапорець навпроти «Бібліотеки об’єктів Microsoft Excel» і натисніть «OK».
4. Після цього ви можете вставити новий модуль або відкрити не використовуваний.
5. Згодом скопіюйте та вставте наступні коди VBA в цей модуль.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Після цього для зручного доступу вам краще додати новий макрос на панель швидкого доступу.
6. Зрештою, ви можете спробувати.

• По-перше, виберіть джерело електронної пошти, яке містить кнопки голосування.
• Потім натисніть кнопку макросу на панелі швидкого доступу.
• Після того, як цей макрос завершиться, ви зможете перейти до визначеної локальної папки, у якій ви побачите нову книгу Excel.
• Відкрийте цю книгу Excel. Тепер ви побачите статистику голосування, показану на малюнку нижче:

Ніхто не може ґрунтовно уникнути помилок Outlook

Незважаючи на те, що Outlook наділений різноманітними можливостями, немає такої функції, яка допоможе нам уникнути помилок Outlook. Різні фактори можуть спричинити помилки Outlook. Наприклад, якщо ви часто неправильно виходите з Outlook, ви, ймовірно, постраждаєте Корупція PST. У такому випадку у вас немає іншого вибору, крім як користуватися деякими потужними інструментами для порятунку вашого файлу PST, наприклад DataNumen Outlook Repair. Він заробив багато похвал завдяки високому показнику відновлення.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі корумпований mdf та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com