Як пакетно експортувати кілька електронних листів Outlook в один документ Word за допомогою VBA

Якщо ви хочете пакетно експортувати кілька електронних листів Outlook в один документ із словом, ви можете використовувати код VBA, показаний у цій статті. Це може допомогти вам виконати це завдання за лічені секунди.

Я коли-небудь представляв, як перетворити електронну пошту Outlook у документ Word у своїй попередній статті - “2 ефективні методи перетворення електронної пошти Outlook у документ Word". Однак обидва засоби, згадані в цьому пost буде безпорадним у тому випадку, коли ви хочете пакетно експортувати багато електронних листів в один документ Word. Отже, тут ми навчимо вас іншого шляху. Тепер читайте, щоб детально це отримати.

Пакетний експорт кількох електронних листів Outlook в один документ Word

1. To starЗапустіть програму Outlook.
2. Потім, після входу в головне вікно Outlook, вам потрібно натиснути кнопки “Alt + F11”.
3. Далі ви отримаєте доступ до редактора Outlook VBA, в якому вам слід відкрити порожній модуль.
4. Згодом скопіюйте код VBA нижче у відкрите вікно модуля.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Після цього вам краще додати цей новий проект VBA на панель швидкого доступу або стрічку.
6. Зрештою, ви можете спробувати.

• Перш за все, виберіть кілька електронних листів Outlook.
• Потім знайдіть і натисніть на додану кнопку макросу.
• Після того, як вам буде запропоновано “Завершити”, ви зможете перейти до визначеної локальної папки, щоб знайти новий документ Word.
• Відкрийте цей документ, у якому ви зможете побачити всі вибрані електронні листи експортовано.

Тримайте поблизу Могутній інструмент відновлення

Незважаючи на численні функції, Outlook все ще не може бути захищений від помилок. Якщо ви звикли залишати помилки наодинці, з їх накопиченням, збій Outlook відбуватиметься однозначно. У цей момент важливо повернутися до потужного та ефективного інструменту відновлення, наприклад DataNumen Outlook Repair. Він добре розбирається в Виправлення PST. Поки це стосується вас, вам більше не доведеться турбуватися про втрату даних про перспективи.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі пошкоджений mdf та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com