Як швидко прикріпити конкретні слайди PowerPoint Презентація до електронної пошти Outlook

Якщо ви хочете витягти конкретні слайди з PowerPoint презентацію до окремої нової презентації та приєднати до електронної пошти Outlook, ви можете використати спосіб, наведений у цій статті.

Замість прикріплення цілого PowerPoint презентацію до електронного листа, якщо ви хочете прикріпити конкретні слайди презентації, загалом, вам потрібно спочатку скопіювати ці слайди до нової презентації. Це занадто клопітно. Отже, тут ми покажемо вам метод, який може реалізувати його одним рухом.

Прикріпіть конкретні слайди a PowerPoint Презентація на електронну пошту

1. Спочатку відкрийте конкретну PowerPoint Презентація
2. Потім у PowerPoint у вікні програми натисніть клавіші “Alt + F11”, щоб отримати доступ до редактора VBA.
3. Потім у новому вікні створіть новий модуль, натиснувши “Вставити”> “Модуль”.
4. Згодом скопіюйте та вставте наступний код VBA в цей модуль.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Після цього ви можете закрити поточне вікно.
6. Пізніше перейдіть до «Файл»> «Параметри»> «Панель швидкого доступу», щоб додати новий макрос на панель швидкого доступу.
7. Нарешті, ви можете спробувати цей макрос.

• Для початку виберіть конкретні слайди, які ви хочете витягти.
• Потім натисніть кнопку макросу на панелі швидкого доступу.
• Одразу з’явиться електронна пошта Outlook, в якій є файл PowerPoint презентація, витягнута з презентації джерела.

Використовуйте ефективний інструмент відновлення

Як ми всі знаємо, Outlook наділений вбудованою утилітою відновлення - scanpst. Проте він може просто впоратися з невеликими збоями в Outlook. Якщо те, з чим ви стикаєтесь, є серйозною шкодою, це не призведе до наслідків. На той момент вам не залишається нічого іншого, як повернутися до іншого потужного та надійного інструменту ремонту, наприклад DataNumen Outlook Repair. З його допомогою ви зможете врятувати пошкоджений файл Outlook.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі пошкоджений mdf та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com