Paano Mabilis na Alisin ang Dobleng Mga Item ng Outlook sa isang Folder sa pamamagitan ng VBA

Kung gusto mong tanggalin ang mga duplicate na item sa Outlook, ang paghahanap at pag-alis nang paisa-isa ay magiging lubhang mahirap. Ituturo sa iyo ng post na ito kung paano ito mabilis na makumpleto gamit ang Outlook VBA.

Sa aking nakaraang artikulo - “Paano Mabilis na Maghanap at Mag-alis ng Mga Duplicate na Email sa Outlook”, maaari kang matuto ng trick sa paghahanap at pag-alis ng mga duplicate na email, na unang pag-uri-uriin ang mga email ayon sa paksa, pagkatapos ay ayon sa natanggap na oras at pagkatapos ay sa pamamagitan ng mga attachment upang malaman ang mga duplicate na item at panghuli ay piliin ang mga duplicate at pindutin ang “Delete” key. Kahit na ang pamamaraang ito ay tila mas maginhawa, ngunit ito ay mas mahirap kumpara sa paggamit ng Outlook VBA. Sa pamamagitan ng mga sumusunod na VBA code, maaari mong mabilis na alisin ang mga duplicate na item sa pamamagitan lamang ng isang pag-click, kahit na mga email, gawain, contact o appointment. Ngayon basahin upang makuha ang mga code nang detalyado.

Alisin ang Duplicate na Outlook Items sa isang Folder

1. Para magsimula, ilunsad ang iyong programa sa Outlook.
2. Pagkatapos ay pindutin ang mga pindutan ng "Alt + F11".
3. Sa kasunod na window ng editor ng VBA, i-double click upang buksan ang isang module na ginagamit o direktang magpasok ng bagong module sa pamamagitan ng "Insert" > "Module".
4. Susunod na kopyahin at i-paste ang mga sumusunod na VBA code sa module.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Pagkatapos nito, digitally sign ang macro na ito at baguhin ang iyong Outlook macro security level sa mababa.
6. Sa ibang pagkakataon, maaari mong patakbuhin ang bagong proyekto ng VBA na ito. Direktang mag-click sa icon na "Run" sa toolbar.
7. Sa dakong huli, kakailanganin mong pumili ng folder kung saan mo gustong alisin ang mga duplicate na item.
8. Sa wakas, ang mga duplicate na item sa napiling folder ay tatanggalin nang sabay-sabay.

Pangalagaan ang Vulnerable PST Data

Dahil sa ang katunayan na ang PST file ay madaling kapitan ng katiwalian, kaya dapat kang gumastos ng maraming pagsisikap upang pangalagaan ang iyong PST file. Halimbawa, dapat mong pigilan ang Outlook na isara nang hindi wasto. Higit pa rito, kailangan mong maghanda ng matatag Inaayos ang Outlook tool, tulad ng DataNumen Outlook Repair na magagawang iligtas ang iyong PST sa oras.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang mabawi SQL Server at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa