Paano Mabilis na I-export ang Kabuuang Oras na Ginugol sa Mga Outlook Appointment sa Bawat Kategorya ng Kulay

Kung gusto mong gumawa ng ulat tungkol sa kabuuang oras na ginugugol mo sa mga appointment sa bawat kategorya ng kulay, maaari mong gamitin ang paraang ipinakilala sa artikulong ito. Makakatulong ito sa iyo na maisakatuparan ito sa mabilis na oras nang hindi kinakailangang magbilang nang manu-mano.

Maraming mga gumagamit ang sanay na itala ang karamihan sa kanilang mga aktibidad sa kalendaryo ng Outlook. Gayundin, upang mas madaling pamahalaan at maiba ang mga ito, nagtatalaga sila ng mga kategorya sa bawat isa sa mga ito. Sa kasong ito, ang ilang mga gumagamit ay nais na bumuo ng isang ulat na nagpapakita ng kabuuang oras na ginugol sa mga item sa kalendaryo sa bawat kategorya ng kulay. Walang duda, mahirap bilangin at i-input nang manu-mano. Samakatuwid, narito ang isang paraan kung paano magagawa ang gawaing ito sa pamamagitan ng isang simpleng pag-click.

I-export ang Kabuuang Oras na Ginugol sa mga Appointment sa Bawat Kategorya ng Kulay

1. Sa unang lugar, ilunsad ang iyong aplikasyon sa Outlook.
2. Pagkatapos, pagkatapos na pumasok sa window ng Outlook, maaari mong i-tap ang mga pindutan ng key na "Alt + F11".
3. Kasunod, makakakuha ka ng access sa window na "Microsoft Visual Basic para sa Mga Aplikasyon".
4. Susunod, kakailanganin mong paganahin ang “Microsoft Excel Object Library”. Maaari mong i-click ang “Tools” > “Reference” para magawa ito.
5. Pagkatapos, dapat kang maghanap at magbukas ng isang module na hindi ginagamit.
6. Pagkatapos nito, kailangan mong kopyahin ang sumusunod na VBA code sa modyul na ito.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Sa wakas, maaari mong ma-trigger ang macro na ito, kahit na sa pamamagitan ng pag-click sa icon na "Run" sa toolbar o pagpindot sa "F5" key button.
8. Pagkatapos, hihilingin sa iyo na pumili ng isang partikular na kalendaryo.
9. Pagkatapos mong piliin at pindutin ang "OK", ang macro ay patuloy na tatakbo. Pagkatapos nito, magkakaroon ng bagong Excel file na ipapakita sa background.
10. Maa-access mo ito. Ito ay magiging hitsura ng sumusunod na screenshot:

Abangan ang Mga Potensyal na Banta sa Iyong Outlook

Dapat bantayan ng mga user ng Outlook ang lahat ng potensyal na panganib, kabilang ang mga hindi kilalang email attachment, naka-embed na link at mga error ng tao. Kung hindi, maaaring masira ang iyong Outlook anumang oras. Gayundin, ang paggawa ng mga regular na pag-backup ng data ng Outlook at pagpapanatili ng isang espesyal na tool sa pag-aayos ay mga bagay ng pangangailangan. DataNumen Outlook Repair ay isa sa mga pinaka-inirerekomendang kagamitan sa pag-aayos. Maaari itong kumpunihin ang Outlook mga problema sa isang iglap.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang nasira mdf at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa