Paano Mabilis na I-export ang Impormasyon sa Laki ng Lahat ng Mga Folder sa isang PST File sa isang Excel File

Kung nais mong suriin ang impormasyon ng laki ng bawat folder sa isang PST file, maaari mong gamitin ang pamamaraang nakalantad sa artikulong ito. Mabilis nitong mai-export ang impormasyon ng laki ng lahat ng mga folder sa isang PST file sa isang file na Excel.

Kapag ang iyong PST file ay masyadong malaki, maaari mong hilinging suriin ang laki ng bawat folder. Tutulungan ka nitong madaling malaman kung alin ang mas malaki at gumawa ng angkop na pag-archive batay sa laki. Sa pangkalahatan, upang suriin ang laki ng folder, maaari mong i-right click ang isang folder at pagkatapos ay piliin ang "Properties". Sa bagong popup dialog box, maaari mong i-click ang pindutang "Laki ng Folder". Gayunpaman, kung nakalikha ka ng maraming mga folder, isa-isang manu-manong suriin ang impormasyon ng laki ng manu-mano ay isang mahirap. Kaya, kung nais mong i-batch ang makuha ang impormasyon ng laki ng lahat ng mga folder sa isang PST file, maaari mong gamitin ang sumusunod na VBA code. I-export nito ang lahat ng mga pangalan ng folder at impormasyon sa laki sa isang file na Excel nang sabay-sabay.

I-export ang Impormasyon sa Laki ng Lahat ng Mga Folder sa isang PST File sa isang Excel File

1. Para magsimula, ilunsad ang iyong aplikasyon sa Outlook.
2. Pagkatapos ay lumipat sa tab na "Developer" at i-click ang pindutang "Visual Basic" o pindutin ang "Alt + F11" na mga key upang ma-access ang VBA editor.
3. Susunod sa window na "Microsoft Visual Basic for Applications", buksan ang isang module na hindi ginagamit.
4. Kasunod, kopyahin at i-paste ang mga sumusunod na VBA code sa modyul na ito.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Pagkatapos nito, dapat mong itakda ang iyong antas ng seguridad ng Outlook sa mababang.
6. Sa paglaon, maaari kang magkaroon ng isang pagsubok.

• Pindutin ang pindutan ng F5 key sa kasalukuyang window ng macro.
• Pagkatapos hihilingin kang pumili ng isang PST file, tulad ng sumusunod na imahe:
• Matapos pumili ng isang mapagmulang file, magsisimulang i-export ng Outlook ang impormasyon sa laki sa Excel.
• Pagkatapos ng mga pagwawakas ng macro, nakatanggap ka ng isang mensahe tulad ng screenshot sa ibaba.
• Panghuli, magagawa mong mahanap ang file na Excel sa paunang natukoy na lokal na folder. Ang file ng Excel ay magiging katulad ng sumusunod:

Makipag-ugnay sa Madalas na Mga Error sa PST

Dahil ang Outlook ay madaling kapitan ng pagkakamali, maaaring nagdusa ka ng maraming mga isyu sa iyong Outlook. Upang mas mahusay at mas may kakayahang umangkop sa mga nakakainis na mga problema sa PST, ipinapayong panatilihin ang isang karanasan at kagalang-galang na pag-aayos ng utility sa paligid, tulad ng DataNumen Outlook Repair. May kakayahang ayusin ang PST mga problemang tulad ng simoy ng hangin.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang SQL Server pagbawi at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa