Paano Mabilis na I-export ang Outlook Email bilang Image File

Ang ilang mga user ay gustong mag-export ng Outlook email bilang isang image file, gaya ng isang jpg file. Samakatuwid, sa artikulong ito, ipapakilala namin sa iyo kung paano ito makukuha sa pamamagitan ng Outlook VBA code.

Dapat ay natutunan mo ang iba't ibang mga trick para sa pag-export ng isang email bilang text file, Word document at iba pa. Pagkatapos, paano ang pag-export ng email bilang larawan tulad ng JPG file? Tila, walang ganitong function ang Outlook. Ngunit, pagkatapos noon, magbabahagi kami ng mabilis na paraan sa iyo.

Mabilis na I-export ang Outlook Email bilang Image File

1. Para sa panimula, ilunsad ang iyong aplikasyon sa Outlook.
2. Pagkatapos, sa pangunahing window ng Outlook, kumuha ng access sa VBA editor na naaayon sa artikulo – “Paano Patakbuhin ang VBA Code sa Iyong Outlook".
3. Susunod, paganahin ang "MS Word Object Library" at "MS Word PowerPoint Aklatan ng Bagay” sa pamamagitan ng pagtukoy sa artikulong – “Paano Magdagdag ng Sanggunian sa Object Library sa VBA".
4. Susunod, kopyahin at i-paste ang sumusunod na VBA code sa isang blangkong module.

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. Pagkatapos nito, kailangan mong idagdag ang macro sa Quick Access Toolbar.
6. Sa dakong huli, maaari mong isara ang editor ng VBA.
7. Sa ibang pagkakataon, pumili ng email at pindutin ang macro button sa Quick Access Toolbar.
8. Kapag nakumpleto ang macro, maaari kang pumunta sa paunang natukoy na lokal na folder upang mahanap ang na-export na file ng imahe mula sa email na ito.

Kunin ang Data ng Outlook mula sa Masirang File

Maaaring nakakadismaya ka kung ang iyong Outlook file ay nasira nang husto. Sa ganitong sitwasyon, magpapatuloy ka sa pagkuha ng data ng Outlook mula sa nakompromisong file. Ang ilang mga gumagamit ay may posibilidad na gumamit ng tool sa pag-aayos ng inbox. Gayunpaman, kadalasan, hindi ito magkakaroon ng epekto. Samakatuwid, mas makabubuti kung mayroon kang isang mahusay at maaasahang... Ayusin ang PST tool, tulad ng DataNumen Outlook Repair. Maaari nitong i-scan ang corrupt na file at ibalik ang maximum na data nang walang anumang pagkabahala.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang mdf ayusin at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa