Paano Mabilis na I-export ang Lahat ng Hyperlink sa Maramihang Outlook Email sa Excel

Kapag kailangan mong kunin ang lahat ng hyperlink sa isa o higit pang mga email, nakakainis na kopyahin ang mga ito nang paisa-isa. Ituturo sa iyo ng post na ito ang isang paraan upang mabilis na ma-export ang lahat ng hyperlink sa maraming email sa Excel.

Para sa ilang kadahilanan, tulad ng pag-log sa mga hyperlink sa lahat ng iyong ipinadalang email, kakailanganin mong kunin ang mga hyperlink. Nang walang anumang pagdududa, hindi ipinapayong kunin at kopyahin ang mga ito nang manu-mano. Kailangan mong maghangad ng mas matalinong diskarte, tulad ng paggamit ng VBA. Dito ay ibabahagi namin sa iyo ang isang piraso ng VBA code, na maaaring i-export ang lahat ng mga hyperlink sa maraming mga email sa Excel sa pamamagitan ng isang madaling pag-click.

I-export ang Lahat ng Hyperlink sa Maramihang Email sa Excel

1. Upang magsimula, ilunsad ang iyong programa sa Outlook gaya ng dati.
2. Pagkatapos, sa window ng Outlook, kailangan mong pindutin ang mga pindutan ng "Alt + F11".
3. Sabay-sabay, makakakuha ka ng access sa Outlook VBA editor.
4. Kasunod nito, kailangan mong paganahin ang “Microsoft Word Object Library” pati na rin ang “Microsoft Excel Object Library”. I-click ang “Tools” > “References” at pagkatapos ay paganahin ang mga ito sa popup dialog box.
5. Susunod, kailangan mong magbukas ng hindi nagamit na module, kung saan kailangan mong kopyahin ang VBA code sa ibaba sa modyul na ito.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Pagkatapos nito, maaari kang lumabas sa kasalukuyang window ng editor ng VBA.
7. I-access sa ibang pagkakataon ang "Outlook Options" upang i-customize ang Quick Access Toolbar upang idagdag ang bagong idinagdag na macro sa Quick Access Toolbar.
8. Sa wakas maaari kang kumuha ng isang shot:

• Una, sa listahan ng email, piliin ang mga email na ang mga hyperlink ay gusto mong kunin.
• Pagkatapos, mag-click sa pindutan ng macro sa Quick Access Toolbar.
• Kapag natapos na ang macro, makakakuha ka ng Excel file, tulad ng larawan sa ibaba:

Ayusin ang Hindi Inaasahang Mga Isyu sa Outlook

Maaaring mangyari ang mga isyu sa Outlook paminsan-minsan nang walang anumang senyales. Ngunit, sa mga tuntunin ng maliliit na error, maaaring makabawi ang Outlook sa pamamagitan ng isang simpleng pag-restart o tool sa pag-aayos ng inbox. Ngunit kung nakakaranas ng ilang malubhang problema, ang panloob na paraan ay hindi magkakaroon ng mga epekto. Sa puntong ito, ang iyong huling paraan ay talagang isang mas kagalang-galang at matatag na tool, gaya ng DataNumen Outlook Repair.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang nasira mdf at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa