Paano Mabilis na I-compress ang Lahat ng Mga Attachment sa a Zip File sa Iyong Outlook Email

Mga Solusyon sa Outlook Setyembre 29, 2025
Ipamahagi ngayon:

Minsan, baka gusto mong i-compress ang lahat ng mga kalakip sa isang email sa a zip direktang mag-file sa Outlook. Sa kasong ito, maaari mong gamitin ang VBA code na ipinakilala sa artikulong ito upang makamit ang tampok na ito.

Bilang default, may limitasyon sa laki ng kalakip ang Outlook - 20 MB para sa POP3, IMAP o ibang mga web-based email account at 10 MB para sa Exchange account. Kaya, kapag ang kabuuang sukat ng mga kalakip ay lumampas sa limitasyon, makakakuha ka ng mga kaugnay na error. Sa kasong ito, ito ay isang mahusay na pagpipilian upang i-compress ang lahat ng mga attachment sa a zip file.

Mabilis na I-compress ang Lahat ng Mga Attachment sa a Zip File sa Iyong Outlook Email

Gayunpaman, tulad ng nakikita mo, hindi nag-aalok ang Outlook ng isang direktang tampok. Iyon ay upang sabihin, kailangan mo munang zip ang mga file na ito sa hard drive at pagkatapos ay muling ikabit ang bagong nilikha zip file. Sa katotohanan, karamihan sa mga gumagamit ay umaasa na maaari nila itong direktang makamit sa loob ng Outlook. Bilang tugon sa kinakailangang ito, ipapakilala namin kung paano gamitin ang VBA upang maisakatuparan ito sa mga sumusunod.

I-compress ang Lahat ng Attachment sa a Zip talaksan

  1. Sa unang lugar, ilunsad ang iyong aplikasyon sa Outlook.
  2. Pagkatapos ay pindutin ang "Alt + F11" na mga pindutan ng key sa pangunahing window ng Outlook.
  3. Susunod sa bagong window ng editor ng Outlook VBA, magbukas ng isang module.
  4. Kasunod, kopyahin at i-paste ang mga sumusunod na VBA code sa modyul.
Sub ZipAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim objShell As Object
    Dim varTempFolder As Variant
    Dim varZipFile As Variant
 
    'Save the attachments to Temporary folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    varTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "dd-mm-yyyy- hh-mm-ss-")
    MkDir (varTempFolder)
    varTempFolder = varTempFolder & "\"
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
    Set objAttachments = objMail.attachments
    For Each objAttachment In objAttachments
        objAttachment.SaveAsFile (varTempFolder & objAttachment.FileName)
    Next
 
    'Create a new zip file
    varZipFile = InputBox("Specify a name for the new zip file", "Name Zip File", objMail.Subject)
    varZipFile = objFileSystem.GetSpecialFolder(2).Path & "\" & varZipFile & ".zip"
    Open varZipFile For Output As #1
    Print #1, Chr$(80) & Chr$(75) & Chr$(5) & Chr$(6) & String(18, 0)
    Close #1
 
    'Copy all the saved attachments to the new zip file
     Set objShell = CreateObject("Shell.Application")
     objShell.NameSpace(varZipFile).CopyHere objShell.NameSpace(varTempFolder).Items

     'Keep macro running until Compressing is done
     On Error Resume Next
     Do Until objShell.NameSpace(varZipFile).Items.Count = objShell.NameSpace(varTempFolder).Items.Count
        Application.Wait (Now + TimeValue("0:00:01"))
     Loop
     On Error GoTo 0
 
     'Delete all the attachments
     Set objAttachments = objMail.attachments
     While objAttachments.Count > 0
           objAttachments.Item(1).Delete
     Wend
 
     'Add the new zip file to the current email 
     objMail.attachments.Add varZipFile
 
    'Prompt
    MsgBox ("Complete!")
End Sub

VBA Code - Mabilis na I-compress ang Lahat ng Mga Attachment sa a Zip File sa Iyong Outlook Email

  1. Pagkatapos nito, kailangan mong suriin ang iyong mga setting ng macro ng Outlook upang matiyak na pinapayagan ang macro.
  2. Sa paglaon maaari mong idagdag ang bagong proyekto ng VBA sa Quick Access Toolbar ng window ng mensahe tulad ng dati.
  3. Sa paglaon maaari kang magkaroon ng isang pagsubok.
  • Una, lumikha ng isang bagong email at maglakip ng maraming mga file. O buksan lamang ang isang mail na may maraming mga kalakip.
  • Susunod na pag-click sa pindutan ng macro sa Quick Access Toolbar.
  • Mamaya kailangan mong tukuyin ang isang pangalan para sa zip file at pindutin ang "OK". Bilang default, maitatakda itong pareho sa paksa ng mail.Tumukoy ng isang pangalan para sa zip file
  • Nang sabay-sabay, ang lahat ng mga kalakip ay mai-compress sa a zip file, tulad ng sumusunod na screenshot:I-compress ang Lahat ng Attachment sa a Zip talaksan

I-zip ang .Zip Mga Attachment na Direkta sa Outlook

Hindi maiiwasan na makakatanggap ka ng anumang mga kalakip na may ".zip"file extension paminsan-minsan. Sa ganitong sitwasyon, maaaring gusto mong direktang i-unzip ang mga naturang file mula sa loob ng iyong Outlook sa halip na i-save at i-uncompress ang mga ito sa local drive. Kahit na walang ganitong native feature ang Outlook, maaari mo pa ring gamitin ang VBA para makuha ito. Para sa karagdagang detalye, maaari kang sumangguni sa isa pang artikulo – "Paano i-unzip ang .Zip Mga Attachment na Direkta sa Outlook sa pamamagitan ng VBA".

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang sql ayusin at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa

Ipamahagi ngayon:

Mga komento ay sarado.