Paano Magtakda ng Iba't Ibang Default na Oras ng Paalala para sa Iba't ibang Mga Uri ng Mga Na-flag na Item sa Iyong Outlook

Bilang default, awtomatikong gagamitin ng Outlook ang default na oras ng paalala ng mga gawain sa lahat ng uri ng na-flag na item. Gayunpaman, kung nais mong gumamit ng iba't ibang oras ng paalala para sa na-flag na mga item batay sa uri ng item, maaari kang sumangguni sa pamamaraang ipinakilala sa artikulong ito.

Pinapayagan ka ng Outlook na magtakda ng default na oras ng paalala para sa lahat ng na-flag na item, anuman ang uri ng item. Maaari kang pumunta sa menu na "File" at i-click ang "Mga Pagpipilian". Pagkatapos, sa window na "Mga Pagpipilian ng Outlook", maaari mong makita ang pagpipiliang "Default na oras ng paalala" sa tab na "Mga Gawain", tulad ng ipinakita sa sumusunod na screenshot.

Gayunpaman, karamihan sa mga gumagamit ay umaasa na gumamit ng iba't ibang oras ng paalala para sa iba't ibang uri ng mga naka-flag na item, tulad ng "9:00" para sa mga naka-flag na mail at "17:30" para sa mga naka-flag na contact. Ngayon, sa mga sumusunod, tututuon tayo sa halimbawang ito upang ipakilala ang isang paraan.

Magtakda ng Iba't Ibang Default na Oras ng Paalala para sa Iba't ibang Mga Uri ng Mga Na-flag na Item

1. Upang magsimula, ilunsad ang application ng Outlook.
2. Pagkatapos, i-access ang editor ng VBA ng Outlook na may sanggunian sa “Paano Patakbuhin ang VBA Code sa Iyong Outlook".
3. Sa kasunod na window ng "Microsoft Visual Basic for Applications", kopyahin ang sumusunod na code sa proyekto na "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Pagkatapos nito, i-restart ang Outlook upang maisaaktibo ang macro na ito.
5. Mula ngayon, bawat oras na mag-flag ka ng isang email, ang oras ng paalala ay itatakda sa "10:00" sa takdang takdang flag.
6. At kapag nag-flag ka ng isang contact, ang oras ng paalala ay itatakda sa "17:30" sa takdang takdang flag.

Masagasaan ang Mga Problema sa Outlook na may kakayahang umangkop

Maaari kang makaranas ng lahat ng uri ng problema sa iyong Outlook. Kaya, kailangan mong matutunan ang ilang mga hakbang upang harapin ang mga ito nang maaga. Halimbawa, kung madalas na mag-restart ang iyong Outlook, kailangan mong ayusin ang Office o i-disable ang mga third-party add-in, atbp. O kung ang iyong Outlook PST ay nakompromiso, maaari mo munang subukan ang tool sa pag-aayos ng inbox. Kapag nabigo ito, maaari mong ipagpatuloy ang paggamit sa isang malakas na panlabas na tool, tulad ng DataNumen Outlook Repair.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang mdf paggaling at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa