Paano Mag-convert ng Batch at Magkabit ng Maramihang Mga Dokumentong Salita bilang PDF Mga file sa isang Outlook Email

Madaling maglakip ng isang dokumento ng Word bilang a PDF file sa isang email sa Outlook. Gayunpaman, kung nais mong maglakip ng maraming mga dokumento ng Word bilang PDF mga file sa isang email, maaari mong basahin ang artikulong ito. Dito ipapakita namin sa iyo ang isang pamamaraan upang makuha ito.

Upang maglakip ng isang dokumento ng Word bilang PDF Kung nais mong ilipat ang file sa isang email sa Outlook, maaari mo munang buksan ang dokumento ng Word at pumunta sa menu na "File". Pagkatapos, maaari kang lumipat sa tab na "Save & Send", kung saan mayroong buton na "Send as PDF", tulad ng sumusunod na screenshot.

Sa gayon, medyo simple upang maglakip ng isang dokumento ng Word bilang PDF sa isang email. Ngunit, kung nais mong i-convert at maglakip ng maraming mga dokumento ng Word bilang PDF mga file sa isang mail, mas mahusay ka sa paggamit ng sumusunod na paraan. Maaari nitong hayaan kang magawa ito nang maramihan.

Batch convert & Attach Multiple Word Documents bilang PDF Mga file sa isang Email

1. Bilang panimula, tipunin ang mga dokumentong Word na gusto mo sa parehong folder ng Windows.
2. Pagkatapos, ilunsad ang programa ng Outlook.
3. Susunod, kopyahin ang sumusunod na code sa isang hindi nagamit na proyekto o module.

Dim objMail As Outlook.MailItem

Sub BatchAttachMultipleWordDocumentsAsPDFToEmail()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim strWindowsFolder As String

    Set objMail = Outlook.Application.CreateItem(olMailItem)

    'Select the specific Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows folder:", 0, "")

    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"

       Call ProcessFolders(strWindowsFolder)

       objMail.Display
    End If
End Sub

Sub ProcessFolders(strPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim strDocumentName As String
    Dim strPDF As String

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strPath)

    For Each objFile In objFolder.Files
        strFileExtension = objFileSystem.GetExtensionName(objFile)
        If LCase(strFileExtension) = "doc" Or LCase(strFileExtension) = "docx" Then
           Set objWordApp = CreateObject("Word.Application")
           Set objWordDocument = objWordApp.Documents.Open(objFile.Path)

           'Convert document to pdf
           strDocumentName = Left(objWordDocument.Name, (Len(objWordDocument.Name) - Len(strFileExtension)) - 1)
           strPDF = strPath & strDocumentName & ".pdf"
           objWordDocument.ExportAsFixedFormat strPDF, wdExportFormatPDF

           objWordDocument.Close False

           'Attach the pdf to email
           objMail.Attachments.Add strPDF

           Kill strPDF
        End If
    Next

    'Process all folders and subfolders
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
              ProcessFolders (objSubfolder.Path)
           End If
       Next
    End If
End Sub

4. Pagkatapos nito, ilipat ang cursor sa unang subroutine.
5. Kasunod, pindutin ang "F5" upang patakbuhin kaagad ang macro na ito.
6. Sa popup maliit na dialog box, piliin ang folder ng Windows kung saan nakaimbak ang mga mapagkukunang Word na dokumento.
7. Nang sabay-sabay, isang bagong email ay malilikha, kung saan maaari mong makita ang naka-attach PDF mga file, tulad ng sumusunod na screenshost.

Sinalanta ng Mga Troubles ng Outlook

Nagagambala ka ba ng iba't ibang mga problema sa Outlook? Halimbawa, ang Outlook ay madalas na natigil sa estado ng "hindi pagtugon" o ang Outlook PST file ay hindi maa-access, atbp. Sa pangkalahatan, maaari mo munang subukan ang tool sa pag-aayos ng inbox, Scanpst, upang ayusin ang mga isyu sa PST. Gayunpaman, sa mga oras, ang mga problema ay maaaring lampas sa kung ano ang magagawa ng inbuilt na tool. Samakatuwid, mas mahusay mong panatilihin ang isang mas malakas na panlabas na utility sa paligid, tulad ng DataNumen Outlook Repair.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang pag-aayos ng sql at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa