Paano Awtomatikong Magtakda ng Iba't ibang Oras ng Paalala para sa Mga Pagpupulong sa Outlook sa Iba't ibang Kategorya ng Kulay

Kung inuuri mo ang mga pulong sa Outlook ayon sa mga kategorya ng kulay at gustong magtakda ng iba't ibang oras ng paalala para sa mga pulong sa iba't ibang kategorya ng kulay, maaari kang sumangguni sa artikulong ito. Dito ay tuturuan ka naming gawin ito sa Outlook VBA.

Halimbawa, hinahati mo ang mga meeting sa dalawang grupo. Ang isa ay nasa kategoryang kulay na "Offsite" dahil masyadong malayo ang lokasyon ng meeting, at ang isa naman ay nasa kategoryang kulay na "Onsite" dahil narito mismo ang lokasyon. Ngayon, gusto mong awtomatikong itakda ng Outlook ang oras ng paalala ng "offsite" meeting bilang 1 oras bago magsimula at ang "onsite" meeting bilang 15 minuto bago magsimula. Dahil sa kinakailangang ito, pagkatapos nito, ibabahagi namin ang isang mabilis na paraan.

Auto Set Iba't ibang Paalala para sa Mga Pagpupulong sa Iba't ibang Kategorya ng Kulay

1. Upang magsimula, ilunsad ang iyong aplikasyon sa Outlook.
2. Pagkatapos, pindutin ang "Alt + F11" key buttons para ma-access ang VBA editor window.
3. Susunod, sa kasunod na window, kopyahin at i-paste ang VBA code sa ibaba sa proyektong "ThisOutlookSession".

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Pagkatapos, kailangan mong mag-click sa subroutine na "Application_Startup" at pindutin ang buton na "F5" upang patakbuhin ang macro na ito.
5. Simula noon, sa tuwing may idinagdag na bagong pulong sa default na kalendaryo o binago mo ang isang umiiral na pulong, awtomatikong susuriin ng Outlook ang mga kategorya ng pulong at awtomatikong itatakda ang iba't ibang oras ng paalala.

Tanggalin ang Mga Error sa Outlook

Maaaring magkaroon ng iba't ibang isyu sa Outlook paminsan-minsan. Kaya naman, napakahalaga para sa mga user na matutunan kung paano haharapin ang mga isyu sa Outlook. Bilang panimula, mas makabubuting regular kang gumawa ng mga backup ng data ng Outlook. Bukod dito, kung abot-kaya, iminumungkahi na magtago ng isang malakas na... Pag-aayos ng Outlook tool sa malapit, tulad ng DataNumen Outlook Repair. Maaari nitong i-scan ang iyong PST file upang malaman ang mga isyu sa Outlook at pagkatapos ay malutas ang mga ito nang madali.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang sql paggaling at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa