Paano Itatala ang Kabuuang Bilang ng mga Papasok na Email Araw-araw sa isang Excel File

Tuturuan ka ng artikulong ito kung paano ipaalam sa awtomatikong bilangin ng Outlook kung gaano karaming mga email ang iyong natanggap araw-araw at isulat ang numero sa isang file na Excel.

Maraming mga gumagamit ang kinakailangang bilangin ang kabuuang bilang ng mga email na natanggap sa bawat araw. Bilang karagdagan, para sa mas maginhawang suriin sa hinaharap, marami ang nasanay sa pagrekord ng kabuuang bilang sa isang file na Excel. Sa kasong ito, syempre maaari kang magpasyang magbilang at mag-record nang manu-mano araw-araw. Gayunpaman, ito ay medyo mahirap. At baka nakakalimutan mong gawin ito minsan. Samakatuwid, dapat mong hinahangad ang isang madaling gamiting pamamaraan, na maaaring gawing awtomatikong gawin ito ng Outlook. Bilang tugon sa kinakailangang ito, tuturuan namin kayo kung paano gamitin ang VBA upang mapagtanto ito sa mga sumusunod.

Awtomatikong Itala ang Kabuuang Bilang ng Mga Papasok na Email Araw-araw sa isang Excel File

1. Sa simula pa lamang, ilunsad ang iyong aplikasyon sa Outlook.
2. Pagkatapos ay pindutin ang "Alt + F11" mga key shortcut sa pangunahing window ng Outlook.
3. Susunod sa popup VBA editor window, buksan ang proyekto na "ThisOutlookSession".
4. Kasunod, kopyahin at i-paste ang mga sumusunod na VBA code sa proyektong ito.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Susunod, lagdaan ang code na ito at baguhin ang iyong mga setting ng macro ng Outlook upang payagan ang mga naka-sign na macros.
6. Pagkatapos nito, kailangan mong lumikha ng isang umuulit na gawain araw-araw.

• Una, i-click ang pindutang "Bagong Gawain" sa pane ng Mga gawain.
• Sa popup window ng Bagong Gawain, i-click ang pindutang "Pag-ulit".
• Pagkatapos sa kasunod na kahon ng dayalogo, piliin ang "Pang-araw-araw", "Tuwing 1 araw (s)" at "Walang petsa ng pagtatapos" at panghuli na-hit ang "OK".
• Mamaya baguhin ang paksa ng gawain at paalala ayon sa iyong mga pangangailangan.
• Sa paglaon ay i-click ang pindutang "I-save at Isara".

7. Mula ngayon, tuwing may mga alerto sa paalala ng gawaing ito, awtomatikong bibilangin ng Outlook ang mga email na natanggap kahapon at pagkatapos ay itatala ang numero sa file na Excel, tulad ng sumusunod na screenshot:

Pagtakas mula sa Permanenteng PST Data Loss

Walang sinumang handang tumanggap ng permanenteng pagkawala ng data ng PST. Gayunpaman, ang file ng Outlook PST ay madaling kapitan ng katiwalian. Samakatuwid, dapat kang gumawa ng sapat na pag-iingat, tulad ng paggawa ng isang pare-pareho at napapanahong pag-backup ng data ng PST at pagpapanatili ng isang malakas Pagbawi ng PST tool sa paligid, tulad ng DataNumen Outlook Repair.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang pag-aayos ng sql at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa