3 Mabilis na Paraan para Magtanggal ng mga Blangkong Row at Column sa Iyong Word Table

Sa post na ito, ipapaliwanag namin sa iyo ang 3 mabilis na paraan upang magbura ng mga blankong row at column sa iyong Word table.

Ang mga talahanayan ay mahalaga sa isang dokumento, lalo na sa paghawak ng iba't ibang uri ng data. Minsan, ang isang mahabang talahanayan ay maaaring lumampas sa isang pahina at lumampas sa ilan. Kaya kapag ang isang talahanayan ay naging mahaba at kumplikado, may mga hakbang na maaari mong gawin upang pasimplehin ito. Halimbawa, maaari mong tanggalin ang mga hindi kinakailangang blangkong row at column.

Ang sumusunod ay 3 paraan na maaari mong gamitin.

Paraan 1: Manu-manong Magtanggal ng mga Blangkong Row at Column

1. Una, pumili ng row o column sa blangko.
2. Pagkatapos ay i-right click para makuha ang contextual menu. Sa menu, piliin ang “Delete Rows” o “Delete Column” nang naaayon.

Sa kasamaang-palad, hindi ka makakapili ng maraming hindi magkakasunod na row o column at tanggalin ang mga ito kasama ng ganitong paraan. Para sa demand na ito, maaari kang sumangguni sa aming nakaraang artikulo: 5 Mabilis na Paraan sa Batch na Magtanggal ng Maramihang Mga Hanay o Column sa Iyong Word Table

Paraan 2: Batch Tanggalin ang Lahat ng Blangkong Row at Column sa isang Table

Ang Paraan 1 ay may limitasyon. Kaya't iaalok namin sa iyo ang paraan upang i-batch ang pag-alis ng mga row at column sa isang table sa pamamagitan ng mga VBA code.

1. Para magsimula, ilagay ang cursor sa loob ng target na talahanayan.
2. Pangalawa, i-trigger ang VBA editor sa pamamagitan ng pagpindot sa “Alt+ F11”.
3. Sa editor, i-click muna ang "Normal" na proyekto.
4. Pagkatapos i-click ang tab na "Ipasok" sa menu bar.
5. Sa drop-down na menu, piliin ang "Modyul".
6. I-double click ang module upang buksan ito at i-paste ang mga sumusunod na code doon:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Sa wakas, i-click ang "Run" na buton sa menu bar o pindutin ang "F5".

Sa ilang segundo, maaalis mo ang lahat ng mga blangkong row at column sa talahanayang iyon.

Paraan 3: Batch Tanggalin ang Lahat ng Blangkong Row at Column sa Lahat ng Table sa isang Dokumento

1. Una, ulitin ang mga hakbang sa paraan 2 para mag-install at magpatakbo ng macro.
2. Sa pagkakataong ito lamang, palitan ang macro na iyon ng mga sumusunod:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Bawiin ang Sirang Dokumento

Mayroong higit pa sa isang paraan upang maibalik ang nawalang data sa kasalukuyan. Halimbawa, ang paggamit ng mga backup ay palaging nananatiling iyong pangunahing prayoridad. Kung hindi nito natutugunan ang iyong pangangailangan na maibalik ang pinakabagong impormasyon, maaari mong subukan ang isang pag-aayos ng doc tool.

Panimula ng May-akda:

Si Vera Chen ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang pag-aayos ng xlsx at pdf pagkumpuni ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa