2 Mga Paraan para I-print ang Mga Listahan ng Mga Gawain sa Outlook na may Iba't ibang Kategorya sa Iba't ibang Pahina

Kung nagtalaga ka ng iba't ibang kategorya ng kulay sa iyong mga gawain sa Outlook at ngayon ay gusto mong i-print ang mga listahan ng mga gawain na may iba't ibang kategorya sa iba't ibang pahina, maaari kang sumangguni sa artikulong ito. Dito ay ibabahagi namin sa iyo ang 2 paraan upang makuha ito.

Upang maiuri at maayos na pamahalaan ang iyong mga gawain, marahil ay naglapat ka ng mga kategorya ng kulay sa iyong mga gawain. Ngayon, kung gusto mong i-print ang mga listahan ng iyong mga gawain na may iba't ibang kategorya sa iba't ibang pahina, mangyaring basahin. Sa mga sumusunod, ipapakilala namin sa iyo ang 2 paraan upang makuha ito.

Paraan 1: Manu-manong I-print ang Mga Listahan ng Gawain Isa-isa

1. Una, sa Outlook, i-access ang "Tasks" pane.
2. Pagkatapos, magbukas ng Task folder.
3. Susunod, pindutin ang “Ctrl + E” para i-activate ang “Search” ribbon.
4. Pagkatapos nito, sa tab na "Paghahanap", i-click ang pindutang "Kategorya".
5. Mula sa drop down na listahan, pumili ng kategorya ng kulay.
6. Pagkatapos, tanging ang mga gawain na may napiling kategorya ang maiiwan sa listahan.
7. Ngayon, pumunta sa “File” > “Print” para i-print ang listahan ng gawaing ito.
8. Kasunod nito, sa parehong paraan, i-print nang manu-mano ang mga listahan ng mga gawain kasama ang iba pang mga kategorya ng kulay.

Paraan 2: Batch Print ang Mga Listahan ng Gawain sa pamamagitan ng VBA

1. Sa pinakasimula pa lang, i-trigger ang VBA editor na alinsunod sa “Paano Patakbuhin ang VBA Code sa Iyong Outlook".
2. Pagkatapos, idagdag ang sanggunian sa “MS Excel Object Library” ayon sa “Paano Magdagdag ng Sanggunian sa Object Library sa VBA".
3. Susunod, kopyahin ang sumusunod na VBA code sa isang module.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Pagkatapos, pindutin ang pindutan ng "F5" key upang patakbuhin ang macro na ito kaagad.
5. Kapag natapos na ang macro, ang mga listahan ng mga gawain na may iba't ibang kategorya ay ipi-print sa iba't ibang mga pahina, tulad ng ipinapakita sa sumusunod na screenshot.

Ibalik ang Mahalagang Data mula sa Nakompromisong PST File

Kung napapailalim ka sa hindi naa-access na PST file, ang iyong susunod na hakbang ay walang alinlangan Pagkumpuni ng PST. Sa kasong ito, maaari mo munang subukan ang tool sa pag-aayos ng inbox. Kung nabigo ito, maaari kang magpatuloy upang subukan ang isa pang panlabas na tool, tulad ng DataNumen Outlook Repair. Nagagawa nitong mabawi ang data ng PST sa mabilis na panahon.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang bawiin mdf at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa