2 Mabilis na Paraan upang Makahanap o Tanggalin ang Mga Pangungusap na Naglalaman ng Tiyak na Teksto sa Iyong Salita

Sa artikulong ito, mag-aalok kami sa iyo ng 2 mabilis na paraan upang maghanap o magtanggal ng mga pangungusap na naglalaman ng tiyak na teksto sa iyong Salita.

Alam ng lahat na maaari nating gamitin ang function na "Find and Replace" sa Word upang madaling mahanap ang lahat ng paglitaw ng mga partikular na salita. Kung gayon, wala tayong magiging problema sa pag-highlight, pagpapalit, o pag-alis ng mga ito. Gaya ng nakikita mo, ang target ay isang salita o parirala. Gayunpaman, ngayon, ikinalulugod naming sabihin sa iyo ang macro na paraan upang mahanap o mabura ang mga pangungusap na naglalaman ng ilang teksto.

Paraan 1: Maghanap o Tanggalin ang Mga Pangungusap na Naglalaman ng Tiyak na Teksto

1. Upang magsimula sa, pindutin ang "Alt + F11" upang ma-trigger ang VBA editor sa Word.
2. Susunod na lumikha ng isang bagong module sa pamamagitan ng pag-click sa "Normal".
3. Pagkatapos ay i-click ang "Ipasok" at piliin ang "Modyul" upang makakuha ng bago.
4. At buksan ang module na may double click.
5. I-paste ngayon ang mga sumusunod na code:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Susunod na pag-click sa "Run".
7. Magkakaroon ng isang kahon ng pag-input, na humihiling sa iyo na magpasok ng teksto. I-type lamang ang karaniwang teksto na naglalaman ng lahat ng mga pangungusap. I-click ang "OK".
8. Pagkatapos ay makikita mo ang isang pangungusap na naglalaman ng teksto sa pagpipilian na may isang kahon ng mensahe na pinapataas. I-click ang "Oo" upang tanggalin ang pangungusap at "Hindi" upang mapanatili ito.
9. Pagkatapos ng kumpirmasyon, ang susunod na pangungusap na may itinalagang teksto ay nasa seleksyon. At nariyan din ang kahon ng pagkumpirma. Ibig sabihin, dadalhin ka ng macro sa buong dokumento, hahanapin ang mga target na pangungusap at hihilingin ang iyong kumpirmasyon sa bawat pagkakataon.

Paraan 2: Maghanap o Tanggalin ang Mga Pangungusap na Naglalaman ng Anumang Teksto sa isang Listahan

Gamit ang macro sa pamamaraan 1, maaari ka lamang maghanap ng isang salita o parirala sa isang pagkakataon. Tiyak, maaari mong patakbuhin ang macro nang paulit-ulit upang maghanap para makahanap ng maraming mga pagkakataon ng mga salita o parirala. Upang matugunan ang pangangailangan ng maraming paghahanap, bibigyan ka namin ng isa pang macro.

1. Ilagay muna ang lahat ng target na teksto sa isang bagong dokumento. Siguraduhing ang bawat piraso ng teksto ay sumasakop sa isang talata na walang espasyo sa likod. Isara at i-save ang dokumento.
2. Susunod na pag-install at pagpapatakbo ng isang macro na may eksaktong mga hakbang sa pamamaraan 1.
3. Pagkatapos palitan ang macro ng isang ito:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Ngayon ang window na "Mag-browse" ay magbubukas. Piliin ang dokumento na nai-save lamang at i-click ang "Buksan".
5. Ang sumusunod na pamamaraan ay kapareho ng sa pamamaraan 1.

Diskarte upang Makipagtulungan sa Mga Dokumentong Masigla

Ang pagkawala ng mahalagang data ay ganap na nagwawasak. Maaari pa ring iwan ang pusta sa iyong negosyo. Upang maiwasan ang nasabing pagkabigo, kailangan mong hawakan ang a Pag-aayos ng salita tool sa lalong madaling panahon. Ang nasabing tool ay makakatulong sa iyo na manalo sa laban sa katiwalian ng dokumento.

Panimula ng May-akda:

Si Vera Chen ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang ayusin ang Excel at pdf pagkumpuni ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa