2 Paraan para Mabilis na Magbilang ng Mga Email ng Nagpadala sa Iyong Outlook

Kung gusto mong bilangin ang mga email sa pamamagitan ng nagpadala, maaari kang sumangguni sa artikulong ito. Dito ilalantad namin sa iyo ang 2 mabilis na diskarte.

Para malaman ang pinaka-aktibong nagpadala para sa iyo, maaari mong bilangin ang mga email ayon sa nagpadala. Bagama't walang direktang tampok ang Outlook para dito, maaari ka pa ring maghanap ng ilang mga solusyon, tulad ng sumusunod na Paraan 1. Kung sa tingin mo ay masyadong nakakapagod ang Paraan 1, maaari mong piliin ang Paraan 2. Mas epektibo ito dahil ginagamit nito ang VBA para mabilis na bilangin ang mga email ayon sa nagpadala at i-export ang mga bilang sa Excel. Ngayon, basahin nang detalyado ang dalawang paraan. Dito ay kukuha tayo ng mga email sa Inbox bilang isang halimbawa.

Paraan 1: Kumuha ng Mga Bilang pagkatapos ng Pagpapangkat ng Mga Item ayon sa Field na "Mula".

1. Upang magsimula sa, ilunsad ang application ng Outlook.
2. Pagkatapos, buksan ang folder ng inbox.
3. Susunod, lumipat sa tab na "Tingnan".
4. Pagkatapos, piliin ang "Mula sa" sa pangkat na "Ayusin".
5. Sabay-sabay, ang lahat ng mga item sa inbox ay pinaghiwalay sa iba't ibang grupo ayon sa iba't ibang mga nagpadala.
6. Ngayon, upang mabilang ang mga item mula sa isang partikular na nagpadala, maaari mong piliin ang lahat ng mga item sa kaugnay na grupo at pindutin ang "Enter" key. Sa popup na babala, makikita mo ang bilang.

Ang ibig sabihin nito ay medyo madali, ngunit ang mga bilang ng item ay aktwal na kasama ang iba pang mga uri ng mga item, tulad ng mga imbitasyon sa pagpupulong, mga kahilingan sa gawain at mga resibo, hindi lamang ang mga bilang ng email. Kaya, kung gusto mo lang magbilang ng mga email, maaari mong gamitin ang sumusunod na paraan sa halip.

Paraan 2: Bilangin ang Mga Email ayon sa Nagpadala gamit ang Outlook VBA

1. Para sa panimula, pindutin ang mga pindutan ng "Alt + F11" sa Outlook.
2. Pagkatapos, paganahin ang “MS Excel Object Library” ayon sa “Paano Magdagdag ng Sanggunian sa Object Library sa VBA".
3. Susunod, kopyahin ang code sa ibaba sa isang hindi nagamit na module.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. Pagkatapos nito, pindutin ang "F5" key button.
4. Kapag natapos ang macro, isang bagong Excel file ang ipapakita.
5. Gaya ng nakikita mo, naglalaman ito ng mga bilang ng mga email sa inbox mula sa iba't ibang mga nagpadala.

Itapon ang Nakakadismaya na Mga Problema sa Outlook

Marahil ay napapailalim ka na sa maraming problema sa iyong Outlook. Upang matugunan ang mga ito nang epektibo, maaari kang maghangad ng maraming nalalaman at makapangyarihang paraan. Gayunpaman, sa katunayan, walang ganoong pamamaraan. Ang magagawa mo ay mag-ingat sa sarili mong mga operasyon sa Outlook at gumawa ng mga regular na backup. Siyempre, kung maaari, iminumungkahi namin na mas mabuting panatilihin mong madaling gamitin ang isang bihasang tool sa pag-aayos, tulad ng DataNumen Outlook Repair. Maaari itong ayusin ang iba't ibang mga isyu sa PST at ayusin tiwaling PST mag-file tulad ng isang simoy.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang mabawi Sql Server at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa