2 Mga Paraan upang Batch Tanggalin Lahat ng Mga contact nang walang Email Address sa Iyong Outlook

Kung may makita kang ilang contact na walang email address sa iyong Outlook, maaari mong iproseso ang bawat folder ng Contact para burahin ang lahat ng naturang contact. Ibabahagi sa iyo ng post na ito ang 2 paraan.

Marahil ay marami kang mga contact sa iyong Outlook at ang ilan sa kanila ay walang email address. Kung sa palagay mo ay hindi na sila kapaki-pakinabang, dapat mong asahan na tanggalin ang lahat ng mga contact nang walang email address. Sa karaniwang paraan, maaari mong gamitin ang "Instant na Paghahanap" upang hanapin ang mga ito at pagkatapos ay manu-manong tanggalin ang mga ito, tulad ng sumusunod na Paraan 1. Gayunpaman, medyo nakakapagod. Samakatuwid, sa Paraan 2, magtuturo kami sa iyo ng isa pang mas mahusay na paraan.

Paraan 1: Manu-manong Tanggalin pagkatapos ng Paghahanap ng Mga contact nang walang Email Address

1. Para sa panimula, pindutin ang "Ctrl + 3" keys upang ma-access ang "Contacts" pane.
2. Pagkatapos, mag-click sa box para sa paghahanap.
3. Susunod, sa umuusbong na laso na "Paghahanap", i-click ang "Lahat ng Mga Item sa Pakikipag-ugnay".
4. Kasunod, mag-click sa "May Address"> "May Email Address".
5. Pagkatapos nito, idagdag ang pamantayan na "HINDI emailaddresses: = []" sa box para sa paghahanap. Kailangan mong alisin ang "HINDI".
6. Kasunod, ang lahat ng mga contact na walang email address ay nakalista.
7. Ngayon, dapat mong piliin ang mga contact sa mga resulta ng paghahanap nang manu-mano sa dapat ang iyong mga pangkat ng contact ay nasa listahan din.
8. Panghuli, pindutin ang "Del" na pindutan ng key upang tanggalin ang lahat ng mga napiling contact.

Paraan 2: Batch Tanggalin Lahat ng Mga contact nang walang Email Address na may VBA

1. Sa una, mag-tap sa "Alt + F11" upang ilunsad ang VBA editor sa Outlook.
2. Sa bagong screen, kopyahin ang sumusunod na VBA code sa isang module.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Mamaya, mag-click sa "BatchDeleteAllContactsWithoutEmailAddress" subroutine.
4. Sa paglaon, pindutin ang "F5" upang ma-trigger ang macro na ito.
5. Kapag nakumpleto ito, makakakuha ka ng isang mensahe tungkol sa mga resulta, tulad ng imahe sa ibaba.
6. Ang lahat ng mga contact na walang email address ay inilipat sa folder na "Tinanggal na Mga Item".

Malayo sa Lahat ng Mga Potensyal na Panganib

Maaaring mapinsala ang Outlook dahil sa iba't ibang mga kadahilanan, tulad ng mga virus, error sa gumagamit, pagkabigo ng software pati na rin mga pagkakamali sa hardware. Dapat kang mag-atubili na makaranas ng pinsala sa Outlook, kaya kailangan mong panatilihin ang lahat ng mga potensyal na panganib na ito. Halimbawa, kailangan mong i-mount ang potent na antivirus software sa iyong PC. Dagdag pa, kailangan mong i-back up ang iyong data sa Outlook sa isang regular na batayan. Huling ngunit hindi pa huli, mas mabuti mong maghanda ng isang matatag at maaasahang tool sa pag-aayos, tulad ng DataNumen Outlook Repair. Maaari itong ayusin ang iyong tiwaling PST madali nang mag-file.

Panimula ng May-akda:

Si Shirley Zhang ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang SQL Server katiwalian at pananaw sa pag-aayos ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa