วิธีส่งออกรายการหมวดหมู่สีของกล่องจดหมาย Outlook ทั้งหมดไปยัง Excel อย่างรวดเร็ว

โซลูชัน Outlook September 29, 2025
แบ่งปันเลย:

บางทีคุณอาจมีบัญชีอีเมลมากกว่าหนึ่งบัญชีที่กำหนดค่าไว้ใน Outlook และกล่องจดหมายแต่ละกล่องมีประเภทสีต่างกัน หากคุณต้องการส่งออกรายการประเภทสีของกล่องจดหมายทั้งหมดไปยัง Excel คุณสามารถใช้วิธีการที่แนะนำในบทความนี้

ตัวอย่างเช่น คุณต้องการแบ่งปันประเภทสีของคุณกับบุคคลอื่น หรือคุณต้องการเปรียบเทียบประเภทสีของกล่องจดหมายต่างๆ ในสถานการณ์สมมตินี้ คุณจะต้องส่งออกรายการประเภทสีของกล่องจดหมายของคุณ ที่นี่เราจะสอนให้คุณรับผ่านรหัส VBA เกี่ยวกับวิธีใช้ VBA คุณสามารถดูได้ที่ – “วิธีเรียกใช้รหัส VBA ใน Outlook ของคุณ"ส่งออกรายการประเภทสีของกล่องจดหมาย Outlook ทั้งหมดไปยัง Excel อย่างรวดเร็ว

ส่งออกรายการประเภทสีของกล่องจดหมาย Outlook ทั้งหมดไปยัง Excel

  1. เริ่มต้นด้วยการเข้าถึงโปรแกรมแก้ไข Outlook VBA ผ่านทาง“ Alt + F11”
  2. จากนั้น ในหน้าต่างใหม่ ให้เปิดใช้งาน “MS Excel Object Library” โดยอ้างอิงจากบทความ – “วิธีการเพิ่มการอ้างอิงไลบรารีอ็อบเจ็กต์ใน VBA"
  3. จากนั้นใส่รหัส VBA ต่อไปนี้ลงในโมดูล
Sub ExportAllColorCategories()
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objStores As Outlook.Stores
    Dim objStore As Outlook.Store
    Dim objCategories As Outlook.Categories
    Dim objCategory As Outlook.Category
    Dim nLastRow As Integer
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    Set objStores = Outlook.Application.Session.Stores
 
    For i = objStores.Count To 1 Step -1
        Set objStore = objStores.Item(i)
        Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
 
        With objExcelWorksheet
             .Cells(1, 1) = "Category"
             .Cells(1, 1).Font.Size = 12
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 2) = "Color"
             .Cells(1, 2).Font.Size = 12
             .Cells(1, 2).Font.Bold = True
       End With
 
       Set objCategories = objStore.Categories
 
       For Each objCategory In objCategories
           nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
           With objExcelWorksheet
                .Cells(nLastRow, 1) = objCategory.Name
                .Cells(nLastRow, 2) = GetColor(objCategory.Color)
                .Cells(nLastRow, 2).Interior.Color = GetRGB(objCategory.Color)
           End With
       Next
 
       objExcelWorksheet.Name = objStore.DisplayName
       objExcelWorksheet.Columns("A:B").AutoFit
    Next
End Sub

Function GetColor(Color) As String
    Select Case Color
           Case -1
                GetColor = "No Color"
           Case 15
                GetColor = "Black"
           Case 8
                GetColor = "Blue"
           Case 23
                GetColor = "Dark Blue"
           Case 20
                GetColor = "Dark Green"
           Case 25
                GetColor = "Dark Maroon"
           Case 22
                GetColor = "Dark Olive"
           Case 17
                GetColor = "Dark Orange"
           Case 18
                GetColor = "Dark Peach"
           Case 24
                GetColor = "Dark Purple"
           Case 16
                GetColor = "Dark Red"
           Case 12
                GetColor = "Dark Steel"
           Case 21
                GetColor = "Dark Teal"
           Case 19
                GetColor = "Dark Yellow"
           Case 13
                GetColor = "Gray"
           Case 5
                GetColor = "Green"
           Case 10
                GetColor = "Maroon"
           Case 7
                GetColor = "Olive"
           Case 2
                GetColor = "Orange"
           Case 3
                GetColor = "Peach"
           Case 9
                GetColor = "Purple"
           Case 1
                GetColor = "Red"
           Case 11
                GetColor = "Steel"
           Case 6
                GetColor = "Teal"
           Case 4
                GetColor = "Yellow"
           Case Else
                GetColor = "Unknown"
    End Select
End Function

Function GetRGB(Color) As Long
    Select Case Color
           Case -1
                GetRGB = RGB(255, 255, 255)
           Case 15
                GetRGB = RGB(0, 0, 0)
           Case 8
                GetRGB = RGB(115, 155, 203)
           Case 23
                GetRGB = RGB(42, 99, 168)
           Case 20
                GetRGB = RGB(0, 126, 0)
           Case 25
                GetRGB = RGB(126, 0, 126)
           Case 22
                GetRGB = RGB(138, 172, 70)
           Case 17
                GetRGB = RGB(226, 107, 10)
           Case 18
                GetRGB = RGB(151, 120, 7)
           Case 24
                GetRGB = RGB(103, 66, 130)
           Case 16
                GetRGB = RGB(192, 0, 0)
           Case 12
                GetRGB = RGB(82, 110, 144)
           Case 21
                GetRGB = RGB(49, 147, 98)
           Case 19
                GetRGB = RGB(180, 176, 0)
           Case 13
                GetRGB = RGB(224, 224, 244)
           Case 5
                GetRGB = RGB(0, 176, 80)
           Case 10
                GetRGB = RGB(216, 136, 176)
           Case 7
                GetRGB = RGB(181, 205, 133)
           Case 2
                GetRGB = RGB(249, 176, 115)
           Case 3
                GetRGB = RGB(255, 218, 185)
           Case 9
                GetRGB = RGB(171, 153, 195)
           Case 1
                GetRGB = RGB(255, 113, 113)
           Case 11
                GetRGB = RGB(204, 216, 218)
           Case 6
                GetRGB = RGB(123, 211, 167)
           Case 4
                GetRGB = RGB(255, 255, 0)
           Case Else
                GetRGB = RGB(255, 255, 255)
     End Select
End Function

รหัส VBA - ส่งออกรายการประเภทสีของกล่องจดหมาย Outlook ทั้งหมดไปยัง Excel

  1. ในที่สุด คลิกเข้าไปในรูทีนย่อย “ExportAllColorCategories” แล้วกด “F5”
  2. เมื่อแมโครเสร็จสิ้น สมุดงาน Excel ใหม่จะปรากฏขึ้น มีลักษณะเหมือนภาพหน้าจอต่อไปนี้รายการหมวดหมู่สีที่ส่งออกในไฟล์ Excel

จัดระเบียบรายการ Outlook ของคุณ

Outlook ให้หมวดหมู่สีแก่ผู้ใช้ซึ่งมีวัตถุประสงค์เพื่อจัดระเบียบรายการต่างๆ มีการใช้งานโดยผู้ใช้จำนวนมาก นอกเหนือจากการจัดระเบียบไฟล์ที่ดีแล้ว ขอแนะนำให้เก็บไฟล์ Outlook ของคุณให้มีขนาดเล็ก ไฟล์ PST ขนาดใหญ่มีแนวโน้มที่จะเสียหาย ในกรณีที่ PST เสียหาย คุณไม่มีทางเลือกอื่นนอกจากพยายามทำสิ่งที่ยาก ซ่อม PST ด้วยเครื่องมือที่ทรงพลัง เช่น DataNumen Outlook Repair.

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ กู้คืน mdf และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.

แบ่งปันเลย:

ความเห็นถูกปิด