วิธีคัดลอกโครงสร้างโฟลเดอร์อย่างรวดเร็วจากไฟล์ Outlook PST หนึ่งไปยังอีกไฟล์หนึ่งผ่าน VBA

โซลูชัน Outlook September 29, 2025

หากคุณต้องการคัดลอกโครงสร้างโฟลเดอร์จากไฟล์ Outlook PST หนึ่งไปยังอีกไฟล์หนึ่งคุณสามารถใช้วิธีการที่แนะนำในบทความนี้ซึ่งจะสอนวิธีใช้ VBA เพื่อให้ได้ในครั้งเดียว

บางทีเพื่อให้จัดการอีเมลของคุณได้ดีขึ้นคุณได้สร้างโฟลเดอร์แบบกำหนดเองหลายโฟลเดอร์ในไฟล์ Outlook หลักของคุณ ดังนั้นเมื่อสร้างไฟล์ Outlook PST ใหม่คุณอาจต้องการใช้โครงสร้างโฟลเดอร์เดียวกัน อันที่จริงในบทความก่อนหน้าของฉัน -“2 ขั้นตอนในการรักษาระดับโครงสร้างโฟลเดอร์ปัจจุบันไว้ในไฟล์ Outlook ใหม่” คุณสามารถเรียนรู้วิธีการแบบดั้งเดิมซึ่งใช้คุณลักษณะ“ เก็บถาวร” เพื่อให้บรรลุ อย่างไรก็ตามจริงๆแล้วมันยังค่อนข้างน่าเบื่อ เมื่อเทียบกับมันการใช้รหัส VBA เพื่อรับมันจะเร็วกว่ามาก ดังนั้นในขั้นตอนต่อไปนี้เราจะบอกขั้นตอนและรหัสโดยละเอียด

คัดลอกโครงสร้างโฟลเดอร์จากไฟล์ Outlook PST หนึ่งไปยังอีกไฟล์หนึ่ง

ขั้นแรก ให้เปิดโปรแกรม Outlook ของคุณก่อน
จากนั้นในหน้าต่าง Outlook ให้กดปุ่ม "Alt + F11"
ถัดไปคุณจะเข้าสู่หน้าต่างตัวแก้ไข Outlook VBA
จากนั้นคัดลอกและวางรหัส VBA ต่อไปนี้ลงในโมดูลใหม่

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

หลังจากนั้นให้เปลี่ยนระดับความปลอดภัยของมาโครเป็นระดับต่ำ
จากนั้นกลับไปที่หน้าต่างแก้ไข VBA แล้วกดปุ่ม "F5" เพื่อเรียกใช้มาโคร
สุดท้ายหลังจากมาโครทำงานเสร็จคุณจะได้รับข้อความแจ้งว่า“ เสร็จสมบูรณ์!”
ณ จุดนี้คุณสามารถไปที่บานหน้าต่างนำทางอีเมล คุณจะเห็นไฟล์ข้อมูล Outlook ใหม่ซึ่งอยู่ในโครงสร้างโฟลเดอร์เดียวกับไฟล์ PST ต้นทางดังภาพด้านล่าง:

รับมือกับปัญหา PST ที่ทำให้สิ้นหวัง

เนื่องจาก Outlook PST มักเกิดข้อผิดพลาดคุณหลายคนต้องเคยพบปัญหาต่างๆใน Outlook ต้องเผชิญกับพวกเขาก่อนอื่นคุณสามารถใช้เครื่องมือซ่อมแซมกล่องขาเข้า Outlook เพื่อทดลองใช้ หากล้มเหลวคุณสามารถใช้เครื่องมือของบุคคลที่สามที่มีศักยภาพมากขึ้นเช่น DataNumen Outlook Repair, ซึ่งสามารถ แก้ไข Outlook ข้อผิดพลาด PST เป็นเรื่องง่าย

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ SQL Server แก้ไขปัญหา และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.