วิธีแปลงรูปภาพที่ฝังทั้งหมดเป็นไฟล์แนบในอีเมล Outlook ของคุณอย่างรวดเร็ว

โซลูชัน Outlook September 29, 2025

หากคุณต้องการเปลี่ยนรูปภาพทั้งหมดที่ฝังอยู่ในเนื้อหาข้อความเป็นไฟล์แนบอีเมลอย่างรวดเร็ว คุณไม่จำเป็นต้องลบและแนบใหม่ด้วยตนเอง คุณสามารถใช้โค้ด VBA ที่เปิดเผยในบทความนี้ได้

บางครั้ง คุณอาจต้องการแบทช์เปลี่ยนรูปภาพที่ฝังไว้ทั้งหมดเป็นไฟล์แนบ ตัวอย่างเช่น รูปภาพในเนื้อหาข้อความมากเกินไปจะขัดจังหวะการอ่านข้อความในเนื้อหาของคุณ ดังนั้น คุณต้องการลบออกจากเนื้อหาอีเมลและเพิ่มเป็นไฟล์แนบแทน แน่นอน คุณสามารถทำได้ด้วยตนเอง แต่จะต้องสะดวกกว่านี้หากเครื่องมือหรือรหัส VBA ใด ๆ สามารถทำได้ในครั้งเดียว ที่นี่เราจะเปิดเผยรหัส VBA ดังกล่าวให้กับคุณ

แปลงรูปภาพที่ฝังทั้งหมดเป็นไฟล์แนบอย่างรวดเร็ว

อันดับแรก ให้เปิดโปรแกรม Outlook ของคุณ
จากนั้นคุณสามารถเปลี่ยนไปที่แท็บ "นักพัฒนา" และกดปุ่ม "Visual Basic"
ถัดไป คุณจะเข้าสู่หน้าต่างตัวแก้ไข Outlook VBA
ต่อจากนั้น คุณต้องคัดลอกโค้ด VBA ต่อไปนี้ลงในโมดูลเปล่า

Sub TurnEmebeddedImagestoAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFile As String
    Dim i As Long
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection.Item(1)
    End Select

    Set objAttachments = objMail.attachments
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    MkDir (strTempFolder)
 
    'Save all embedded images to temp folder
    For i = objAttachments.Count To 1 Step -1
        Set objAttachment = objAttachments.Item(i)
        If IsEmbedded(objAttachment) = True Then
           objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.FileName
        End If
    Next
 
    'Add extracted images as attachments
    strTempFolder = strTempFolder & "\"
    strFile = Dir(strTempFolder)
 
    While Len(strFile) > 0
          objMail.attachments.Add (strTempFolder & strFile)
          strFile = Dir
    Wend
 
    'Remove embedded images from message body
    With objMail
        .BodyFormat = olFormatPlain
    End With
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

หลังจากนั้น คุณควรยืนยันว่า Outlook ของคุณได้รับการตั้งค่าให้อนุญาตมาโคร
อีกทางเลือกหนึ่ง ถ้าคุณต้องการสิ่งนี้บ่อยๆ คุณควรเพิ่มแมโครใหม่ลงในแถบเครื่องมือด่วนเพื่อการตรวจสอบที่สะดวกในอนาคต
ในที่สุดคุณสามารถลอง เลือกหรือเปิดอีเมลแล้วเรียกใช้แมโครโดยคลิกปุ่มแมโครใหม่ในแถบเครื่องมือด่วน
ทันที รูปภาพที่ฝังไว้ทั้งหมดจะเปลี่ยนเป็นไฟล์แนบดังภาพหน้าจอต่อไปนี้:

เคล็ดลับในการปกป้องข้อมูล Outlook อันมีค่าของคุณ

อย่างที่เราทราบกันดีว่าไฟล์ Outlook PST มีช่องโหว่เช่นเดียวกับไฟล์ทั่วไป เช่น เอกสาร Word หรือสเปรดชีต Excel ดังนั้น คุณควรคอยระวังความเสี่ยงทั้งหมดเกี่ยวกับไฟล์ PST ของคุณ เช่น ไวรัสหรือการจัดการที่ไม่เหมาะสม ดังนั้นคุณต้องสำรองข้อมูลไฟล์ PST เป็นประจำ นอกจากนี้ ถ้าคุณสามารถจ่ายได้ ก็ควรที่จะรักษาความแข็งแกร่งไว้ ซ่อมแซม Outlook เครื่องมือที่มีประโยชน์เช่น DataNumen Outlook Repair.

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ กู้คืน mdf และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.