วิธีแยกผู้รับทั้งหมดออกจากไฟล์ข้อความ Outlook (.msg) หลายไฟล์อย่างรวดเร็ว

ผู้ใช้บางรายต้องการแยกผู้รับทั้งหมดอย่างรวดเร็วจากไฟล์ข้อความ Outlook หลายไฟล์ที่บันทึกจากอีเมล Outlook ตอนนี้หน้านี้ost จะดูสิ่งนี้เพื่อแบ่งปันแนวทางที่รวดเร็ว

ในการแยกผู้รับออกจากไฟล์ข้อความ Outlook ไฟล์เดียวคุณสามารถดับเบิลคลิกเพื่อเปิดไฟล์จากนั้นคัดลอกผู้รับในหน้าต่างข้อความที่เปิดอยู่ แต่ถ้าคุณต้องการจัดการกับไฟล์ข้อความ Outlook จำนวนมากวิธีการแบบแมนนวลนั้นไม่มีประสิทธิภาพเพียงพอ ดังนั้นคุณอาจมองหาวิธีที่มีประสิทธิภาพมากขึ้น ที่นี่เราจะแนะนำสิ่งนี้ให้คุณ อ่านเพื่อรับรายละเอียด

แยกผู้รับทั้งหมดออกจากไฟล์ข้อความ Outlook (.msg) หลายไฟล์

1. สำหรับเป็นtart, เข้าถึงโปรแกรมแก้ไข Outlook VBA ตาม "วิธีเรียกใช้รหัส VBA ใน Outlook ของคุณ"
2. จากนั้นคัดลอกและวางรหัส VBA ต่อไปนี้ลงในโมดูลว่าง

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. จากนั้นเลื่อนเคอร์เซอร์ในรูทีนย่อยแรก
4. จากนั้นคลิกปุ่ม“ Run” หรือกดปุ่ม“ F5”
5. จากนั้นในกล่องโต้ตอบป๊อปอัปให้เลือกโฟลเดอร์ Windows ที่มีไฟล์ข้อความ Outlook (.msg) ต้นทาง
6. หลังจากเลือกแล้วให้คลิก“ ตกลง” เพื่อให้มาโครทำงานต่อไป
7. เมื่อมาโครเสร็จสิ้นข้อความที่แสดงที่อยู่อีเมลของผู้รับที่แยกออกมาทั้งหมดจะปรากฏขึ้นดังที่แสดงในภาพหน้าจอต่อไปนี้

ปกป้องข้อมูล Outlook ของคุณจากอันตราย

ข้อมูล Outlook มีแนวโน้มที่จะเกิดความเสียหาย ดังนั้นจึงเป็นงานที่ค่อนข้างยุ่งยากในการปกป้องข้อมูล Outlook คุณต้องอดทนในการสำรองข้อมูล Outlook เป็นประจำ นอกจากนี้หากเป็นไปได้ควรมีความรอบคอบและแนะนำให้เตรียม Outlook ที่มีประสบการณ์และเป็นมืออาชีพ ซ่อม PST เครื่องมือเช่น DataNumen Outlook Repairเพื่อให้คุณได้รับการช่วยเหลืออย่างทันท่วงทีและทันท่วงทีในกรณีที่ Outlook เสียหาย

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ กู้ Sql Server และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.