วิธีการแบทช์เปิดไฮเปอร์ลิงก์ทั้งหมดด้วยโดเมนเฉพาะในอีเมล Outlook ของคุณ

เมื่อดูอีเมล Outlook ที่มีการเชื่อมโยงหลายมิติจำนวนมากในบางครั้งคุณอาจต้องการเปิดไฮเปอร์ลิงก์อย่างรวดเร็วด้วยโดเมนเฉพาะ เราจะแบ่งปันวิธีการเปิดการเชื่อมโยงหลายมิติดังกล่าวเป็นกลุ่ม

เมื่อมีการเชื่อมโยงหลายมิติหลายรายการในอีเมลเดียวคุณอาจต้องการตรวจสอบบางส่วนแทนทั้งหมด ตัวอย่างเช่นคุณต้องการเปิดการเชื่อมโยงหลายมิติเป็นกลุ่มด้วยโดเมนเฉพาะ โดยทั่วไปคุณต้องคลิกทีละรายการเพื่อเปิด มันลำบากมาก ดังนั้นต่อไปนี้เราจะสอนวิธีที่สะดวกกว่าให้คุณ

แบทช์เปิดไฮเปอร์ลิงก์ทั้งหมดด้วยโดเมนเฉพาะในอีเมล

1. สำหรับเป็นtart เข้าถึงโปรแกรมแก้ไข Outlook VBA ตาม "วิธีเรียกใช้รหัส VBA ใน Outlook ของคุณ"
2. จากนั้นในหน้าต่าง“ Microsoft Visual Basic for Applications” ให้เปิดใช้งานการอ้างอิงถึง“ MS Word Object Library” โดยอ้างอิงถึง“วิธีเพิ่ม Object Library การอ้างอิงใน VBA"
3. จากนั้นคัดลอกรหัส VBA ต่อไปนี้ลงในโมดูลหรือโครงการที่ไม่ได้ใช้

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. จากนั้นเพิ่มมาโครนี้ลงในแถบเครื่องมือด่วนหรือริบบิ้น
5. สุดท้ายทำตามขั้นตอนต่อไปนี้เพื่อทดลองใช้

• ก่อนอื่นให้เลือกหรือเปิดอีเมล Outlook
• จากนั้นคลิกปุ่มมาโคร
• ในครั้งเดียวไฮเปอร์ลิงก์ที่มีโดเมนที่กำหนดไว้ล่วงหน้าในอีเมลจะถูกเปิดเป็นกลุ่มใน Internet Explorer ดังที่แสดงในภาพต่อไปนี้:

กำจัดการทุจริตของ Outlook ที่ระคายเคือง

แม้ว่า Outlook จะอ่อนไหวต่อข้อผิดพลาดและความเสียหาย แต่จริงๆแล้วตราบใดที่คุณมองหาความเสี่ยงทั้งหมดคุณก็สามารถหลีกหนีจากความเสี่ยงได้อย่างง่ายดาย ตัวอย่างเช่นคุณต้องทำการสำรองข้อมูลสำหรับ Outlook เป็นประจำ นอกจากนี้คุณควรระวังอีเมลที่น่าสงสัยซึ่งอาจมีไวรัส สุดท้าย แต่ไม่ท้ายสุดคุณควรเตรียมไฟล์ ซ่อมแซม Outlook ยูทิลิตี้เช่น DataNumen Outlook Repair. สามารถช่วยคุณได้ในกรณีที่ Outlook เสียหาย

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ ทุจริต SQL Server และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.