วิธีการแบทช์ลบใบตอบรับการอ่านทั้งหมดใน Outlook ของคุณ

เพื่อยืนยันว่าผู้รับได้อ่านอีเมลของคุณแล้ว คุณสามารถขอใบตอบรับการอ่านขณะเขียนอีเมลได้ ในกรณีนี้ กล่องจดหมายของคุณอาจเต็มไปด้วยใบตอบรับการอ่านดังกล่าว บทความนี้จะสอนวิธีลบใบตอบรับการอ่านเหล่านั้นอย่างถาวรเป็นชุดๆ

หลังจากอ่านบทความ“วิธีการแบทช์ลบใบเสร็จการจัดส่งทั้งหมดใน Outlook ของคุณ“ คุณอาจคิดถึงวิธีการลบใบตอบรับการเปิดอ่านทั้งหมดจำนวนมาก ในความเป็นจริงความแตกต่างที่ชัดเจนระหว่างใบเสร็จรับเงินทั้งสองประเภทคือเรื่องของพวกเขา ใบเสร็จการจัดส่งมี "จัดส่งแล้ว" ในหัวเรื่อง แต่ใบตอบรับการอ่านจะมี "อ่านแล้ว" แทน ดังนั้นคุณสามารถใช้วิธีเดียวกันนี้ในการลบใบตอบรับการอ่านทั้งหมดได้ ต่อไปนี้เราจะสอนขั้นตอนที่เป็นรูปธรรมโดยละเอียด

Batch ลบใบตอบรับการอ่านทั้งหมด

1. เริ่มแรก ให้เปิดโปรแกรม Outlook ขึ้นมา
2. จากนั้นไปที่โปรแกรมแก้ไข Outlook VBA ผ่าน“ Alt + F11” ตาม“วิธีเรียกใช้รหัส VBA ใน Outlook ของคุณ"
3. ถัดไปในหน้าต่างใหม่เปิดโมดูลที่ว่างเปล่าและใส่รหัสต่อไปนี้ลงไป

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. หลังจากนั้นคลิกเข้าไปในรูทีนย่อยแรก
5. สุดท้ายกดปุ่ม“ F5”
6. ในครั้งเดียวแมโครจะทำงานเพื่อลบใบตอบรับการอ่านทั้งหมดออกจาก Outlook ของคุณ
7. เมื่อเสร็จสิ้นคุณจะได้รับข้อความแจ้งเกี่ยวกับผลลัพธ์ดังเช่นภาพหน้าจอด้านล่าง
8. ในปัจจุบันคุณสามารถตรวจสอบโฟลเดอร์อีเมลของคุณได้ ใบตอบรับการเปิดอ่านทั้งหมดหายไปแล้ว

ปกป้องข้อมูล Outlook

แม้ว่าไฟล์ Outlook จะเสี่ยงต่อความเสียหาย แต่เราสามารถดำเนินการเพื่อป้องกันได้ ตัวอย่างเช่นเราควรเก็บไฟล์ Outlook ให้มีขนาดเล็กป้องกันจากปัจจัยที่เป็นอันตรายและสำรองข้อมูลไว้เป็นประจำ สุดท้าย แต่ไม่ท้ายสุดคุณควรเตรียมเครื่องมือซ่อมแซม PST ภายนอกที่มีศักยภาพเช่น DataNumen Outlook Repair. มันจะส่งผลดีอย่างมากในการซ่อม Outlook เสียหาย ไฟล์

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ ซ่อม sql และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.