2 วิธีในการพิมพ์รายการงาน Outlook ที่มีหมวดหมู่ต่างๆในหน้าต่างๆ

โซลูชัน Outlook September 29, 2025
แบ่งปันเลย:

หากคุณได้กำหนดประเภทสีต่างๆให้กับงาน Outlook ของคุณและตอนนี้ต้องการพิมพ์รายการงานที่มีหมวดหมู่ต่างๆในหน้าต่างๆคุณสามารถอ้างถึงบทความนี้ได้ ที่นี่เราจะแบ่งปัน 2 วิธีในการรับ

เพื่อจัดหมวดหมู่และจัดการงานของคุณได้เป็นอย่างดีบางทีคุณอาจใช้ประเภทสีกับงานของคุณ ตอนนี้หากคุณต้องการพิมพ์รายการงานของคุณด้วยหมวดหมู่ต่างๆในหน้าต่างๆโปรดอ่านต่อ ต่อไปนี้เราจะแนะนำ 2 วิธีที่จะได้รับ

วิธีที่ 1: พิมพ์รายการงานด้วยตนเองทีละรายการ

  1. ก่อนอื่นใน Outlook ให้เข้าถึงบานหน้าต่าง "งาน"
  2. จากนั้นเปิดโฟลเดอร์งาน
  3. จากนั้นกด“ Ctrl + E” เพื่อเปิดใช้งาน Ribbon“ Search”
  4. หลังจากนั้นบนแท็บ "ค้นหา" คลิกปุ่ม "จัดหมวดหมู่"
  5. จากรายการแบบเลื่อนลงให้เลือกประเภทสีค้นหาตามหมวดหมู่
  6. จากนั้นจะเหลือเฉพาะงานในหมวดหมู่ที่เลือกไว้ในรายการเหลือเฉพาะงานที่มีประเภทสีเฉพาะเท่านั้น
  7. ตอนนี้ไปที่“ ไฟล์”>“ พิมพ์” เพื่อพิมพ์รายการงานนี้พิมพ์งานที่พบในรายการ
  8. จากนั้นพิมพ์รายการงานด้วยหมวดหมู่สีอื่น ๆ ด้วยตนเองในลักษณะเดียวกัน

วิธีที่ 2: ชุดพิมพ์รายการงานโดย VBA

  1. ในตอนแรกให้ทริกเกอร์โปรแกรมแก้ไข VBA ตาม "วิธีเรียกใช้รหัส VBA ใน Outlook ของคุณ"
  2. จากนั้นเพิ่มการอ้างอิงถึง“ MS Excel Object Library” ตาม“วิธีเพิ่ม Object Library การอ้างอิงใน VBA"
  3. จากนั้นคัดลอกรหัส VBA ต่อไปนี้ลงในโมดูล
Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

รหัส VBA - พิมพ์รายการงาน Outlook ที่มีหมวดหมู่ต่างๆในหน้าต่างๆ

  1. หลังจากนั้นให้กดปุ่ม“ F5” เพื่อเรียกใช้มาโครนี้ทันที
  2. เมื่อมาโครเสร็จสิ้นรายการงานที่มีหมวดหมู่ต่างๆจะถูกพิมพ์ในหน้าต่างๆดังที่แสดงในภาพหน้าจอต่อไปนี้พิมพ์รายการงาน

รับข้อมูลที่มีค่ากลับคืนจากไฟล์ PST ที่ถูกบุกรุก

หากคุณอยู่ภายใต้ไฟล์ PST ที่ไม่สามารถเข้าถึงได้ขั้นตอนต่อไปของคุณก็ไม่ต้องสงสัย ซ่อม PST. ในกรณีนี้ขั้นแรกคุณสามารถลองใช้เครื่องมือซ่อมแซมกล่องจดหมายได้ หากล้มเหลวคุณสามารถดำเนินการต่อเพื่อลองใช้เครื่องมือภายนอกอื่นเช่น DataNumen Outlook Repair. สามารถกู้คืนข้อมูล PST ได้ในเวลารวดเร็ว

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ กู้คืน mdf และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.

แบ่งปันเลย:

ความเห็นถูกปิด