Kako hitro najti odstavke z enim stavkom v dokumentu Word

V tej objavi vam želimo pokazati hiter način za iskanje vseh enostavčnih odstavkov v vašem Wordovem dokumentu prek VBA.

Občasno imajo nekateri dokumenti lahko zelo posebne zahteve glede njihovega oblikovanja in struktur. Na primer, morda ne boste smeli imeti odstavkov z enim stavkom. Teh odstavkov ni težko prepoznati, vendar je potreben čas, še posebej to je dolg dokument.

Danes vam bomo ponudili hiter način določanja vseh enostavčnih odstavkov v dokumentu.

Poišči vse odstavke z enim stavkom v enem dokumentu

1. Prvič, Word šteje obdobje kot stavek. Torej, če obstajajo besede, kot je "g." ali »gospa«, Word to razume kot stavek. Če želite izključiti takšno motnjo, morate zamenjati besedo "g." z "gospod". In ko končate najti odstavek enega stavka, jih lahko spremenite nazaj. Če želite zamenjati besede, se lahko obrnete na to povezavo: Kako najti in zamenjati več elementov v dokumentu Word
2. Drugič, pritisnite “Alt + F11”, da sprožite urejevalnik VBA.
3. Nato kliknite »Normal« projekt.
4. V menijski vrstici kliknite jeziček »Vstavi« in v spustnem meniju izberite »Modul«.
5. Nato dvokliknite modul, da ga odprete.
6. Na modul prilepite naslednje kode:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Nenazadnje kliknite gumb »Zaženi« ali pritisnite »F5«.

Prejeli boste takšno okence s sporočilom, da je delo končano.

Poiščite vse odstavke z enim stavkom v več dokumentih

1. Za začetek morate vse ciljne dokumente shraniti v mapo.
2. Nato namestite in zaženite spodnji makro:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. V odprtem oknu »Brskaj« izberite mapo, v kateri hranite dokumente, in kliknite »V redu«.

Nato bo makro označil vse odstavke z enim stavkom in pustil dokumente odprte. Če dokument ne vsebuje enostavčnega odstavka, bo zaprt. Poleg tega je v oknu s sporočilom navedeno število enostavčnih odstavkov v vsakem dokumentu.

Odpravite incident z izgubo podatkov

Napake uporabnikov in nenaden izpad električne energije lahko privedejo do mrtvega v Wordu. Medtem ko zrušena beseda ne more vplivati ​​samo na vsakodnevno delo, ampak tudi lahko vodi do doc škodaTo nikakor ni najbolj nadležen del podatkovne katastrofe. Bolje je, da takoj poiščete orodje za popravilo, ki bo obnovilo podatke.

Uvod avtorja:

Vera Chen je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z izterjati excel in pdf popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com